Esercizio 1

Dobbiamo risolvere il Problema di Cauchy y’’-2y’+2y=1, y(0)=2, y’(0)=-1. L’abbiamo ricavato per sostituzione a partire dal sistema di ODE di ordine 1 nel testo dell’esercizio. Risolviamo il problema di Cauchy per verificare la soluzione

DSolve[{y''[t]-2 y'[t]+2 y[t]-1==0,y[0]==2,y'[0]==-1},y,t]

Calcoliamo i coefficienti (Subscript[c, 1])(t) e (Subscript[c, 2])(t) della soluzione particolare ottenuta con il metodo della variazione delle costanti

Integrate[-(E^(-t)) Sin[t],t]

Integrate[(E^(-t)) Cos[t],t]

Due soluzioni indipendenti dell’omogenea associata sono (Subscript[y, 1])(t)=(e^t)Cos(t), (Subscript[y, 2])(t)=(e^t)Sin(t). Una soluzione particolare si scrive (Subscript[y, 1])(Subscript[c, 1])+(Subscript[y, 2])(Subscript[c, 2])

FullSimplify[(E^t) Cos[t] ((1/2) (E^(-t)) (Cos[t]+Sin[t]))+(E^t) Sin[t] ((1/2) (E^(-t)) (-Cos[t]+Sin[t]))]

Esercizio 2

Calcoliamo l’esponenziale (e^At), dove

A={{4 ,1,3 },{0,4 ,2 },{0,0,4 }};

MatrixForm[A t]

Controlliamo che la matrice esponenziale sia quella trovata nell’esercizio

MatrixForm[MatrixExp[A t]]

Calcoliamo il polinomio Caratteristico di A:

Factor[CharacteristicPolynomial[A,x]]

Per il Teorema di Hamilton-Cayley anche A “soddisfa” la sua equazione caratteristica:

MatrixForm[MatrixPower[(A- 4 IdentityMatrix[3]),3]]

Esercizio 3

Scriviamo la funzione quadrato della distanza da (2,1,-1) di un punto (x,y,z)∈(ℝ^3) e minimizziamola sul piano Π={(x,y,z) : x+y-z=1}.

dist[x_,y_,z_]:=(((x-2))^2)+(((y-1))^2)+(((z+1))^2);

Minimize[{dist[x,y,z],x+y-z==1},{x,y,z}]

Il quadrato della distanza minima è dunque 3. La distanza minima è (Sqrt[3]) ed è realizzata dal punto (1,0,0). Esso è il punto di interezione della retta r perpendicolare al piano Π e passante per (2,1,-1).

Disegnamo la retta r (l’equazione è stata ricavata nell’esercizio)

r3=ParametricPlot3D[{x,x-1,1-x},{x,-5,5},Mesh->None,ColorFunctionScaling->False,PlotStyle->{Tube[.03]},AxesLabel->{x,y,z}];

Disegnamo i due punti (2,1,-1) e (1,0,0)

p3=ListPointPlot3D[{{2,1,-1},{1,0,0}},PlotStyle->PointSize[.03]];

Disegnamo il piano Π

P3=ContourPlot3D[{x+y-z==1},{x,-5,5},{y,-5,5},{z,-5,5},AxesLabel->{x,y,z},Mesh->None];

Vediamo se la retta r perpendicolar a Π per (2,1,-1) passa per (1,0,0)

Show[r3,p3,P3]

Esercizio 4

Disegnamo M. Si tratta di un’ellissoide di semiassi [-2,2], [-1,1], [-3,3].

ContourPlot3D[9 (x^2)+36 (y^2)+4 (z^2)==36,{x,-3,3},{y,-3,3},{z,-3,3},ContourStyle->{Directive[Opacity[0.5]]},AxesLabel->{x,y,z},AspectRatio->1,Mesh->None]

Disegnamo lo spazio tangente ad M in un suo punto ((Subscript[x, 0]),(Subscript[y, 0]),(Subscript[z, 0])), che abbiamo visto essere l’insieme
Π= {(x,y,z) : 18 (Subscript[x, 0])(x-(Subscript[x, 0]))+72(Subscript[y, 0])(y-(Subscript[y, 0]))+8 (Subscript[z, 0])(z-(Subscript[z, 0]))=0}. Scegliamo ad esempio il punto (1,(1/2),(3/(Sqrt[2]))).

E4=ContourPlot3D[9 (x^2)+36 (y^2)+4 (z^2)==36,{x,-4,4},{y,-4,4},{z,-4,4},ContourStyle->{Directive[Opacity[0.5]]},AxesLabel->{x,y,z},AspectRatio->1,Mesh->None];

P4=ContourPlot3D[18 (x-1)+36 (y-(1/2))+(24/(Sqrt[2])) (z-(3/(Sqrt[2])))==0,{x,-4,4},{y,-4,4},{z,-4,4},ContourStyle->{Directive[Opacity[0.5]]},AxesLabel->{x,y,z},AspectRatio->1,Mesh->None];

p4=ListPointPlot3D[{{1,0.5,(3/(Sqrt[2]))}},PlotStyle->PointSize[.02]];

Show[E4,P4,p4]

Calcoliamo il massimo della funzione 8xyz quando (x,y,z) è sull’ellisse. Questa funzione è legata al volume del parallelepipedo inscritto con facce parallele ai piani coordinati che ha un vertice in (x,y,z).

MaxValue[{8 x y z, 9 (x^2)+36 (y^2)+4 (z^2)==36&&x>0&&y>0&&z>0},{x,y,z}]

NMaximize[{8 x y z, 9 (x^2)+36 (y^2)+4 (z^2)==36},{x,y,z}]

N[{(16/(Sqrt[3])),(2/(Sqrt[3])),(1/(Sqrt[3])),(3/(Sqrt[3]))}]

Vediamo come si comportano i parallelepipedi inscritti in M

Manipulate[Grid[{{Show[ContourPlot3D[9 (x^2)+36 (y^2)+4 (z^2)==36,{x,-2,2},{y,-1,1},{z,-3,3},ContourStyle->{Directive[Opacity[0.5]]},AxesLabel->{x,y,z},AspectRatio->1,Mesh->None],RegionPlot3D[-s≤x≤s&&-t≤y≤t&&- (Sqrt[9-(9/4) (s^2)-9 (t^2)])≤ z≤(Sqrt[9-(9/4) (s^2)-9 (t^2)]),{x,-2,2},{y,-1,1},{z,-3,3},PlotPoints->20,Mesh->None]],RegionPlot3D[-s≤x≤s&&-t≤y≤t&&- (Sqrt[9-(9/4) (s^2)-9 (t^2)])≤ z≤(Sqrt[9-(9/4) (s^2)-9 (t^2)]),{x,-2,2},{y,-1,1},{z,-3,3},PlotPoints->20,Mesh->None]}, {"Il parallelepipedo con vertice " ,"Il suo volume è"},{((s .  t . (Sqrt[9-(9/4)(s^2)-9 (t^2)]))),8 s t (Sqrt[9-(9/4)(s^2)-9 (t^2)]) }}],{s,0.0000001,2-0.00000001},{t,0.00000001,(Sqrt[1-((s^2)/4)])-0.0000001}]

Esercizio 5

Disegnamo la funzione f sul rettanglo [0,2]x[-1,2]

f5[x_,y_]:=(x^3)+(y^3)-3 x y;

Solve[Grad[f5[x,y],{x,y}]==0,{x,y},Reals]

Plot3D[{(x^3)+(y^3)-3 x y},{x,0,2},{y,-1,2},AxesLabel->{x,y},PlotRange->{-1,13},Mesh->None]

I punti critici per la funzione su (ℝ^2) sono (0,0) e (1,1). Disegnamo la funzione ristretta ai quattro lati

p51=Plot[f5[0,y],{y,-1,2}];

p52=Plot[f5[2,y],{y,-1,2}];

p53=Plot[f5[x,-1],{x,0,2}];

p54=Plot[f5[x,2],{x,0,2}];

GraphicsGrid[{{p51,p52,p53,p54}},ImageSize->1000]

Nell’esercizio abbiamo trovato punti critici per la funzione f ristretta ai quattro lati, ovvero quando la derivata delle funzioni su rappresentate è nulla. In particolare, i punti (0,0) (prima immagine), (2,(Sqrt[2])) (seconda immagine), ((Sqrt[2]),2) (quarta immagine). Come possiamo vedere in questo modo però non abbiamo individuato come critici anche i punti che sono ai quattro vertici del rettangolo. Quindi dovremo valutare la funzione pure qui. Valutiamo la funzione in tutti i punti critici (interni e sui lati) e sui quattro vertici: Il massimo e il minimo saranno tra questi punti. 
f(1,1)=f(0,-1)=-1 sono punti di minimo assoluto. Il punto (2,-1) è punto di massimo assoluto. Il fatto che dobbiamo controllare ANCHE i vertici è più chiaro se guardiamo il grafico della funzione all’inizio dell’esercizio.

Esercizio 6

Disegnamo l’inisieme M ed il punto (0,0,1)

t6=ContourPlot3D[{z-Cos[Pi y]==0,(x^2)+(y^2)+(z^2)==1},{x,-1,1},{y,-1,1},{z,-1,1},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Red,Tube[.02]}}},Boxed->False,ColorFunctionScaling->False,AxesLabel->{x,y,z}];

p6=ListPointPlot3D[{{0,0,1}},PlotStyle->PointSize[.03]];

Show[t6,p6]

Si tratta di una curva il (ℝ^3). Il punto (0,0,1) è quello evidenziato in blu, e si vede essere un punto singolare. L’insieme M\(0,0,1) è una varietà differenziale. In (0,0,1) non è possibile definire uno spazio tangente. Disegnamo lo spazio tangente nel punto (((Sqrt[3])/2),(1/2),0). Esso sarà una retta. Abbiamo visto essere la retta in (ℝ^3) di equazioni  πy+z=(π/2),(Sqrt[3])x+y=2, ovvero la retta di direzione (1,-(Sqrt[3]), π(Sqrt[3])) e passante per  (((Sqrt[3])/2),(1/2),0)

p61=ListPointPlot3D[{{(Sqrt[3])/2,1/2,0}},PlotStyle->PointSize[.03]];

r6=ParametricPlot3D[{x,2-(Sqrt[3])x,π/2-π (2-(Sqrt[3])x)},{x,-1,1},Mesh->None,ColorFunctionScaling->False,PlotStyle->{Tube[.02]},AxesLabel->{x,y,z}];

Show[t6,p61,r6]

Chiaramente M è compatto poichè chiuso e limitato. Disegnamo la funzione f definita su M a valori in ℝ. La rappresenteremo come un gradiente di colore.

f6=ContourPlot3D[{z-Cos[Pi y]==0,(x^2)+(y^2)+(z^2)==1},{x,-1,1},{y,-1,1},{z,-1,1},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Red,Tube[.02]}}},Boxed->False,ColorFunction->Function[{x,y,z},Hue[ (1/2) ((x^2)+(z^2))]],ColorFunctionScaling->False,AxesLabel->{x,y,z}]

Dal teorema dei moltiplicatori di Lagrange abbiamo visto che per trovare i punti critici giungiamo all’equazione x=0, y=Sin(π y) , z=Cos(π y).

Plot[{x,Sin[Pi x]},{x,-1,1}]

Essa ha due soluzioni diverse da 0. Calcoliamole numericamente. Nell’esercizio le abbiamo indicate con ±a, a>0.

FindRoot[y==Sin[Pi y],{y,0.5}]

FindRoot[y==Sin[Pi y],{y,-0.5}]

za=Cos[Pi 0.7364844482415167` ]

Quindi a ≃ 0.736484.  Disegnamo i due punti (±a,-(Sqrt[1-(a^2)])). L’altro punto estremale è (0,0,1).

t2=ListPointPlot3D[{{0,0.7364844420576713`,-0.6764544729251802`},{0,-0.7364844420576713`,-0.6764544729251802`},{0,0,1}},PlotStyle->PointSize[.03]];

Show[f6,t2]

Calcoliamo f=(x^2)+(z^2) in questi due punti. f(0,0,1)=1, f(0,±a,-(Sqrt[1-(a^2)]))=1-(a^2)<1. (0,0,1) è di massimo assoluto per f su M e (0,±a,-(Sqrt[1-(a^2)])) sono di minimo assoluto per f su M.

Esercizio 7

Disegnamo la regione E

RegionPlot3D[x≥0&&x+(y^2)+(z^2)≤1,{x,0,1},{y,-1,1},{z,-1,1},AxesLabel->{x,y,z}]

Integriamo per fili paralleli all’asse x. Chiaramente la proiezione sul piano yz di E è il disco di cento (0,0) e raggio 1.

Sezione7[z_,y_]:=ParametricPlot3D[{x,y, z}, {x, 0,1-(y^2)-(z^2)}, PlotStyle->Directive[Blue, Thick],BoxRatios->Automatic ,PlotPoints->10];
d7:=RegionPlot3D[x≥0&&x+(y^2)+(z^2)≤1,{x,0,1},{y,-1,1},{z,-1,1},Mesh->None, PlotStyle->{Directive[Opacity[0.6]]},AspectRatio->1,PlotPoints->60,AxesLabel->{x,y,z}];
Show[  d7, Sezione7[0.5,0.5], Sezione7[-0.6,0.4], Sezione7[-0.3, -0.1]]

Calcoliamo l’intgrale di (z^2)  su E

Integrate[(z^2) Boole[x≥0&&x+(y^2)+(z^2)≤1],{x,0,1},{y,-1,1},{z,-1,1}]

Esercizio 8

Disegnamo la regione D. Essa è D={(x,y) : 0 ≤ y ≤3 , (y^2)≤ x ≤9}.

RegionPlot[0≤y≤3&&(y^2)≤x≤9,{y,0,3},{x,0,9}]

Per integrare y Cos((x^2)) su D è conveniente cambiare l’ordine di integrazione. Si vede che D ={(x,y) : 0 ≤ x ≤9 , 0≤ y ≤(Sqrt[x])}. Vediamo

RegionPlot[0≤x≤9&&0≤y≤(Sqrt[x]),{x,0,9},{y,0,3}]

Calcoliamo infine l’integrale

Integrate[y Cos[(x^2)] Boole[0≤y≤3&&(y^2)≤x≤9],{x,0,9},{y,0,3}]

Esercizio 9

Integriamo ((|y((|)^3))/(1+(x^2)(e^(|y|)))) su ℝ rispetto alla variabile x

Integrate[((Abs[y])^3)/(1+(x^2) (E^(Abs[y]))),x]

Limit[(E^(-((Abs[y])/2))) ((Abs[y])^3) ArcTan[(E^((Abs[y])/2)) x],x->+Infinity]-Limit[(E^(-((Abs[y])/2))) ((Abs[y])^3) ArcTan[(E^((Abs[y])/2)) x],x->-Infinity]

Quest’ultima quantità è integrabile su ℝ nella variabile y. Quindi f è in (L^1)((ℝ^2)) poichè il suo modulo è integrabile. Calcoliamo l’integrale di f su (ℝ^2).  f è dispari in y e pari in x, per cui ci aspettiamo che l’integrale sia nullo.

Integrate[((y^3)/(1+(x^2)(E^((Abs[y]))))),{x,-Infinity,+Infinity},{y,-Infinity,+Infinity}]

Infine calcoliamo l’integrale di |f|. Siccome dobbiamo integrare π (e^((|y|)/2))|y((|)^3)  su ℝ, e la funzione è pari, calcoliamo l’integrale su [0,+∞[ : π(∫_ℝ)(e^(-((|y|)/2))) |y((|)^3)dy=2π((∫_0)^(+∞))(e^(-(y/2)))(y^3)dy

Integrate[(y^3) (E^(-y/2)),{y,0,+Infinity}]

Il risultato sarà quindi 2 π 96 = 192 π