Esercizio 8.13

Disegnamo la regione E:={(x,y,z):(x^2)+(y^2)+(z^2)≤ 1}

RegE=RegionPlot3D[x^2+y^2+z^2≤1, {x,-1,1}, {y,-1,1}, {z,-1,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Individuiamo la proiezione di E sul piano (xy)

Reduce[x^2+y^2+z^2<1, z]

RegionPlot[-1<y<1&&-(Sqrt[1-(y^2)])<x<(Sqrt[1-(y^2)]),{x,-1,1},{y,-1,1}]

plott1:=ContourPlot3D[{x^2+y^2==1}, {x,-1 ,1}, {y,-1,1},{z,-1,1}, PlotRange->{-1,1},AspectRatio->1,Mesh->False,ContourStyle->{Directive[Opacity[0.4]]},AxesLabel->{x,y,z}];

plott2:=ContourPlot3D[{z==0}, {x,-1 ,1}, {y,-1,1},{z,-1,1}, PlotRange->{-1,1},AspectRatio->1,Mesh->False,ContourStyle->{Directive[Opacity[0.4]]},AxesLabel->{x,y,z}];

Show[plott1,plott2, RegE]

Individuiamo le (x,y)-Sezioni (ovvero le sezioni verticali)

Reduce[(x^2)+(y^2)+(z^2)<1, {x,y}]

La proiezione sull’asse z è quindi il segmento [-1,1]. Le (x,y) sezioni sono i segmenti -(Sqrt[1-(x^2)-(y^2)]) ≤ z ≤ (Sqrt[1-(x^2)-(y^2)])

Sezione[x_,y_]:=ParametricPlot3D[{x,y, z}, {z, -(Sqrt[(1-((x^2)+(y^2)))]),(Sqrt[1-((x^2)+(y^2))])}, PlotStyle->Directive[Blue, Thick],BoxRatios->Automatic]

d3:=ContourPlot3D[{(x^2)+(y^2)+(z^2)==1}, {x,-1, 1}, {y,-1, 1},{z,-1,1},ContourStyle->{Directive[Opacity[0.6]]}, Mesh->None,AxesLabel->{x,y,z}];

Show[  d3, Sezione[0.4, 0.5], Sezione[0,0], Sezione[-0.3, 0.7]]

Manipulate[Grid[{{Show[d3,Sezione[(1-s) Cos[100 Pi s],(1-s) Sin[100 Pi s]]],ParametricPlot[{(1-r) Cos[100 Pi r],(1-r) Sin[100 Pi r]},{r,s,1},PlotRange->{{-1,1},{-1,1}},PlotPoints->90]}, {"le (xy) sezioni","il punto xy sulla proiezione E(xy)"}}], {s,0.99999,0},PreserveImageOptions->True]

Vediamo ora quali sono le z-sezioni

Manipulate[Grid[{{Plot[{z,-(Sqrt[1-(r^2)]),(Sqrt[1-(r^2)])}, {r, -1,1}, PlotStyle->Thick],Plot3D[{-(Sqrt[1-(x^2)-(y^2)]),(Sqrt[1-(x^2)-(y^2)]),z},{x,-1,1},{y,-1,1},Mesh->None,AspectRatio->1.5,PlotPoints->20,AxesLabel->{x,y,z}], RegionPlot[x^2+y^2≤ 1-(z^2),{x,-1,1}, {y,-1,1}]}, {"","Il piano a quota z","la z-sezione E(z)"}}], {z,-1,1},PreserveImageOptions->True]

Esercizio 8.15

Int[r_]:=Integrate[Abs[x]   Boole[(x^2)+(y^2)+(z^2)≤ (r^2)],{x,-r,r},{y,-r,r},{z,-r,r}]

Int[2];

Integrate[(4/3)((r^2)-(y^2) ) (Sqrt[(r^2)-(y^2)]) ,{y,-r,r},Assumptions->r>0]

Esercizio 8.16 (a=1)

RegE1=RegionPlot3D[x^2+y^2+z^2≤1&&x+y+z≥ 1&&x≥ 0&&y≥ 0&&z≥ 0, {x,0,1}, {y,0,1}, {z,0,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Individuiamo la proiezione sull’asse xy

Reduce[x^2+y^2+z^2<1&&x+y+z>1&&x>0&&y>0&&z>0, z]

RegionPlot[(0<x≤1-y)||(1-y<x<(Sqrt[1-(y^2)])),{x,0,1},{y,0,1}]

Individuiamo le (xy)-sezioni (le sezioni verticali)

Reduce[(x^2)+(y^2)+(z^2)<1&&x+y+z>1&&x>0&&y>0&&z>0, {x,y}]

Sezione16[x_,y_]:=ParametricPlot3D[{x,y, z}, {z, Max[1-x-y,0],(Sqrt[1-((x^2)+(y^2))])}, PlotStyle->Directive[Blue, Thick],BoxRatios->Automatic ];

d16:=RegionPlot3D[x^2+y^2+z^2≤1&&x+y+z≥ 1&&x≥ 0&&y≥ 0&&z≥ 0,{x,0,1},{y,0,1}, {z,0,1},Mesh->None, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}];

Show[  d16, Sezione16[0.6, 0.6], Sezione16[0.1,0.1], Sezione16[0.3, 0.5]]

Calcoliamo l’integrale

Integrate[Boole[(x^2)+(y^2)+(z^2)≤1&&x+y+z≥1&&z≥0&&x≥0&&y≥0],{x,0,1},{y,0,1},{z,0,1}]

Esercizio 8.18

Disegnamo il dominio

RegionPlot3D[x+y^2+z^2<1&&x>0&&x>0, {x,0,1}, {y,-1,1}, {z,-1,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Il dominio è normale rispetto al piano (yz). Calcoliamo la proiezione sul piano (yz)

Reduce[x+y^2+z^2<1&&x>0&&x>0, x]

RegionPlot[-1<z<1&&-(Sqrt[1-(z^2)])<y<(Sqrt[1-(z^2)]),{z,-1,1},{y,-1,1}]

Calcoliamo le (yz)-sezioni (proiezioni sull’asse x)

Reduce[(x^2)+(y^2)+(z^2)<1&&x+y+z>1&&x>0&&y>0&&z>0, {z,y}]

Sezione18[z_,y_]:=ParametricPlot3D[{x,y, z}, {x, 0,1-(y^2)-(z^2)}, PlotStyle->Directive[Blue, Thick],BoxRatios->Automatic ];

d18:=RegionPlot3D[x+y^2+z^2≤1&&x≥ 0,{x,0,1},{y,-1,1}, {z,-1,1},Mesh->None, PlotStyle->{Directive[Opacity[0.6]]},AspectRatio->1,AxesLabel->{x,y,z}];

Show[  d18, Sezione18[0.6, 0.6], Sezione18[-0.1,0.5], Sezione18[0.3, -0.5]]

Calcoliamo l’integrale

Integrate[(z^2)  Boole[x+(y^2)+(z^2)≤1&&x≥ 0],{x,0,1},{y,-1,1},{z,-1,1}]

Esercizio 8.20

Disegnamo il dominio

RegionPlot3D[x>0&&(x^2)+(y^2)<1&&0<z<x, {x,0,1}, {y,-1,1}, {z,0,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z},PlotPoints->30]

Il dominio è normale rispetto al piano (xy). Calcoliamo la proiezione sul piano (xy)

Reduce[x>0&&(x^2)+(y^2)<1&&0<z<x,z]

RegionPlot[0<x<1&&-(Sqrt[1-(x^2)])≤y≤(Sqrt[1-(x^2)]),{x,0,1},{y,-1,1},AspectRatio->2]

Calcoliamo le (xy)-sezioni (proiezioni sull’asse z)

Reduce[x>0&&(x^2)+(y^2)<1&&0<z<x,{x,y}]

Sezione20[x_,y_]:=ParametricPlot3D[{x,y, z}, {z, 0,x}, PlotStyle->Directive[Blue, Thick],BoxRatios->Automatic ,PlotPoints->10];
d20:=RegionPlot3D[x>0&&(x^2)+(y^2)<1&&0<z<x,{x,0,1},{y,-1,1}, {z,0,1},Mesh->None, PlotStyle->{Directive[Opacity[0.6]]},AspectRatio->1,PlotPoints->60,AxesLabel->{x,y,z}];
Show[  d20, Sezione20[0.6, 0.6], Sezione20[0.1,-0.5], Sezione20[0.3, -0.2]]

Calcoliamo l’integrale

Integrate[Boole[x≥0&&(x^2)+(y^2)≤1&&0≤z≤x],{x,-1,1},{y,-1,1},{z,0,1}]

Esercizio 8.21

Disegnamo il dominio

RegionPlot3D[-2<x<2&&(x^2)<y<4&&-(Sqrt[y-(x^2)])<z<(Sqrt[y-(x^2)]), {x,-2,2},{y,0,4},{z,-2,2}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Il dominio è normale rispetto al piano (xy). Troviamo la proiezione sul piano (xy)

Reduce[-2<x<2&&(x^2)<y<4&&-(Sqrt[y-(x^2)])<z<(Sqrt[y-(x^2)]),z]

RegionPlot[-2<x<2&&(x^2)<y<4,{x,-2,2},{y,0,4},AspectRatio->1]

Calcoliamo le (xy)-sezioni

Reduce[-2<x<2&&(x^2)<y<4&&-(Sqrt[y-(x^2)])<z<(Sqrt[y-(x^2)]),{x,y}]

Sezione21[x_,y_]:=ParametricPlot3D[{x,y, z}, {z, -(Sqrt[y-(x^2)]),(Sqrt[y-(x^2)])}, PlotStyle->Directive[Blue, Thick],BoxRatios->Automatic ,PlotPoints->10];
d21:=RegionPlot3D[-2<x<2&&(x^2)<y<4&&-(Sqrt[y-(x^2)])<z<(Sqrt[y-(x^2)]),{x,-2,2},{y,0,4}, {z,-2,2},Mesh->None, PlotStyle->{Directive[Opacity[0.6]]},AspectRatio->1,PlotPoints->60,AxesLabel->{x,y,z}];
Show[  d21, Sezione20[1, 3], Sezione21[-1,2], Sezione21[0.5, 1]]

Calcoliamo l’integrale

Integrate[(1/Pi) Boole[-2≤x≤2&&(x^2)≤y≤4&&-(Sqrt[y-(x^2)])≤z≤(Sqrt[y-(x^2)])],{x,-2,2},{y,0,4},{z,-2,2}]

Esercizio 8.22

Disegnamo il dominio

RegionPlot3D[0≤x≤1&&0≤y≤1&&0≤z≤(x^2), {x,0,1},{y,0,1},{z,0,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Calcoliamo l’integrale

Integrate[z (y^(2 )) (Sqrt[(x^2)+z y]) Boole[0≤z≤(x^2)],{x,0,1},{y,0,1},{z,0,1}]

Esercizio 43

a) Calcolare (∫_E)(x^2)dxdydz dove E={ (x,y,z) : 0 ≤ x ≤ 2 , 0 ≤ y ≤ 2x , 0 ≤ z ≤ x }

Disegnamo il dominio E

RegionPlot3D[0≤x≤2&&0≤y≤2 x&&0≤z≤x,{x,0,2},{y,0,4},{z,0,2}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Dalla definizione del dominio vediamo che si presta all’integrazione per fette parallele al piano (yz)

Manipulate[Grid[{{Show[RegionPlot3D[0≤x≤2&&0≤y≤2 x&&0≤z≤x,{x,0,2},{y,0,4},{z,0,2}, PlotStyle->{Directive[Opacity[0.6]]}],ContourPlot3D[x==s,{x,0,2},{y,0,4},{z,0,2}]], RegionPlot[0≤y≤2 s&&0≤z≤s,{y,0,4}, {z,0,2}]}, {"Il piano a quota x","la x-sezione E(x)=[0,2x]x[0,x]"}}], {s,0,2}]

Quindi conviene calcolare l’integrale sui rettangoli [0,2x]x[0,x] e integrare il risultato in x per x in [0,2]. Con mathematica calcoliamo direttamente l’integrale

Integrate[(x^2) Boole[0≤x≤2&&0≤y≤ 2 x&&0≤z≤x],{x,0,2},{y,0,4},{z,0,2}]

b) Calcolare (∫_E)ydxdydz dove E è il tetraedro delimitato da x=0 , y=0 , z=0 , x+3y+z=4

Disegnamo i quattro piani

ContourPlot3D[{x==0,y==0,z==0,x+3 y+z==4},{x,-4,4},{y,-(4/3),(4/3)},{z,-4,4},ContourStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Abbiamo capito che ci troviamo nella regione x≥0 , y≥0 , z≥0 , x+3y+z≤4. Per cui disegnamo il nostro dominio E

RegionPlot3D[x≥0&&y≥0&&z≥0&&x+3 y+z≤4,{x,0,4},{y,0,(4/3)},{z,0,4},PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Possiamo integrare per fette parallele a uno dei tre piani coordinati. La scelta, come si vede dall’immagine, è equivalente : le nostre “fette” saranno sempre dei triangoli, per cui saranno descritte nello stesso modo. Integriamo, ad esempio, per fette parallele al piano xy.

Manipulate[Grid[{{Show[RegionPlot3D[x≥0&&y≥0&&z≥0&&x+3 y+z≤4,{x,0,4},{y,0,(4/3)},{z,0,4}, PlotStyle->{Directive[Opacity[0.6]]}],ContourPlot3D[z==s,{x,0,4},{y,0,4/3},{z,0,4}]], RegionPlot[0≤x≤4-s &&0≤y≤((4-s-x)/3),{x,0,4}, {y,0,4/3}]}, {"Il piano a quota z","la z-sezione E(z)"}}], {s,0,4}]

Infine calcoliamo l’integrale

Integrate[y Boole[x≥0&&y≥0&&z≥0&&x+3 y+z≤4],{x,0,4},{y,0,4/3},{z,0,4}]

f) Calcolare (∫_E)3(xy^2)(z^3)dxdydz dove E={ (x,y,z) : 0 ≤ x ≤ 1 , 0 ≤ z ≤ x , 0 ≤ y ≤ xz }

Disegnamo la regione E

RegionPlot3D[0≤x≤1&&0≤z≤x&&0≤y≤x z,{x,0,1},{y,0,1},{z,0,1},PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z},PlotPoints->30]

Anche in questo caso, dalla descrizione di E si vede che è conveniente integrare la funzione per fette parallele al piano (yz), siccome compare la condizione x nell’intervallo [0,1]. E per x fissato in [0,1], si tratta di un integrale su un dominio semplice sul piano (yz), già scritto in forma normale rispetto all’asse z.

Manipulate[Grid[{{Show[RegionPlot3D[0≤x≤1&&0≤z≤ x&&0≤y≤x z,{x,0,1},{y,0,1},{z,0,1}, PlotStyle->{Directive[Opacity[0.6]]}],ContourPlot3D[x==s,{x,0,1},{y,0,1},{z,0,1}]], RegionPlot[0≤z≤ s&&0≤y≤s z,{z,0,1}, {y,0,1}]}, {"Il piano a quota x","la x-sezione E(x)"}}], {s,0,1}]

Calcoliamo l’integrale

Integrate[3 x (y^(2  ))(z^3) Boole[0≤x≤1&&0≤z≤x&&0≤y≤x z],{x,0,1},{y,0,1},{z,0,1}]

Esercizio 45

Dobbiamo trovare i limiti di integrazione dell’integrale triplo (∫_E)f(x,y,z)dxdydxz dove E è il tetraedro limitato dal piano x+y+z=1 e dai piani coordinati. Scrivere altri due integrali iterati equivalenti.

Il problema è simile a quello dell’esercizio 43-b. Disegnamo i quattro piani e identifichiamo le disuguaglianze che definiscono la regione E

ContourPlot3D[{x==0,y==0,z==0,x+y+z==1},{x,-1,1},{y,-1,1},{z,-1,1},ContourStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}]

Notiamo che le disuguaglianze da considerare sono x≥0 , y≥0 , z≥0 , x+y+z≤1. Disegnamo la nostra regione E

RegionPlot3D[x≥0&&y≥0&&z≥0&&x+y+z≤1,{x,0,1},{y,0,1},{z,0,1},PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z},PlotPoints->30]

La regione si presta a un’integrazione per fette parallele a uno dei tre assi coordinati. Dalla simmetria del dominio rispetto agli assi, una funzione generica f(x,y,z) si presta a essere integrata per fette parallele a uno qualsiasi dei tre assi coordinati, indipendentemente dalla scelta. Lo possiamo vedere, ad esempio, nella seguente animazione

Manipulate[Grid[{{Show[RegionPlot3D[x≥0&&y≥0&&z≥0&&x+ y+z≤1,{x,0,1},{y,0,1},{z,0,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}],ContourPlot3D[z==s,{x,0,1},{y,0,1},{z,0,1}]], RegionPlot[0≤x≤1-s &&0≤y≤1-s-x,{x,0,1}, {y,0,1}],Show[RegionPlot3D[x≥0&&y≥0&&z≥0&&x+ y+z≤1,{x,0,1},{y,0,1},{z,0,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}],ContourPlot3D[x==s,{x,0,1},{y,0,1},{z,0,1}]], RegionPlot[0≤z≤1-s &&0≤y≤1-s-z,{z,0,1}, {y,0,1}],Show[RegionPlot3D[x≥0&&y≥0&&z≥0&&x+ y+z≤1,{x,0,1},{y,0,1},{z,0,1}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}],ContourPlot3D[y==s,{x,0,1},{y,0,1},{z,0,1}]], RegionPlot[0≤x≤1-s &&0≤z≤1-s-x,{x,0,1}, {z,0,1}]}, {"Il piano a quota z","la z-sezione E(z)","Il piano a quota x
x","la x-sezione E(x)","Il piano a quota y","la y-sezione E(y)"}}], {s,0,1}]

Esercizio 46

Esprimere l’integrale iterato (∫_(-1)^1)(∫_0^(Sqrt[1-(x^2)]))(∫_(-2)^(y+1))f(x,y,z)dxdydz come integrale triplo su un dominio. Scrivere  poi altri due integrali iterati equivalenti.

Iniziamo disegnando la regione nel modo in cui ci è stata fornita a partire dall’integrale iterato

RegionPlot3D[-1≤x≤1&&0≤y≤(Sqrt[1-(x^2)])&&-2≤z≤y+1,{x,-1,1},{y,0,1},{z,-2,2},PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z},PlotPoints->30]

Il dominio sembra effettivamente più semplice da descrivere di come ci è stato fornito...da considerazioni sugli estremi di integrazione per x , y e z capiamo che deve essere 0≤y≤1 , -2≤z≤2 e -(Sqrt[1-(y^2)])≤x≤(Sqrt[1-(y^2)]) (ovvero una porzione di cilindro, a quanto pare...). Possiamo scrivere E={ (x,y,z) : 0≤y≤1 , -2≤z≤2 , -(Sqrt[1-(y^2)])≤(Sqrt[1-(y^2)])}. Disegnamolo:

RegionPlot3D[0≤y≤1&&-2≤z≤y+1&&-(Sqrt[1-(y^2)])≤x≤(Sqrt[1-(y^2)]),{x,-1,1},{y,0,1},{z,-2,2},PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z},PlotPoints->30]

Sembra proprio lui! Proviamo una terza descrizione. Le relazioni precedenti di portano a pensare E={ (x,y,z) : -1≤x≤1 , -2≤z≤2 , 0≤y≤(Sqrt[1-(x^2)])}. Disegnamolo:

RegionPlot3D[-1≤x≤1&&-2≤z≤2&&Max[0,z-1]≤y≤(Sqrt[1-(x^2)]),{x,-1,1},{y,0,1},{z,-2,2},PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z},PlotPoints->30]

Avevamo usato nel precedente esempio, come z-sezioni, E(z)={ (x,y) : -1≤ x ≤1 , max{0,z-1} ≤ y ≤ (Sqrt[1-(x^2)]) }. Ma potevamo usare anche E(z)={ (x,y) : -(Sqrt[1-(y^2)])≤ x ≤(Sqrt[1-(y^2)]) , max{0,z-1} ≤ y ≤ 1 }. Vediamo

RegionPlot3D[-(Sqrt[1-(y^2)])≤x≤(Sqrt[1-(y^2)])&&-2≤z≤2&&Max[0,z-1]≤y≤1,{x,-1,1},{y,0,1},{z,-2,2},PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z},PlotPoints->30]

E’ sempre lo stesso dominio! Abbiamo addirittura ottenuto quattro descrizioni di E. Ed alcune di esse, per una funzione generica da integrare, possono rivelarsi migliori di altre (ad esempio la seconda, in cui le “fette” sono rettangoli!) Questo magari può essere visto anche attraverso il seguente grafico

Manipulate[Grid[{{Show[RegionPlot3D[-1≤x≤1&&0≤y≤ (Sqrt[1-(x^2)])&&-2≤z≤y+1,{x,-1,1},{y,0,1},{z,-2,2}, PlotStyle->{Directive[Opacity[0.6]]},AxesLabel->{x,y,z}],ContourPlot3D[x==s,{x,-1,1},{y,0,1},{z,-2,2}]], RegionPlot[-2≤z≤ y+1&&0≤y≤(Sqrt[1-(s^2)]),{y,0,1}, {z,-2,2}]}, {"Il piano a quota x","la x-sezione E(x)"}}], {s,-1,1}]

Manipulate[Grid[{{Show[RegionPlot3D[-1≤x≤1&&0≤y≤ (Sqrt[1-(x^2)])&&-2≤z≤y+1,{x,-1,1},{y,0,1},{z,-2,2}, PlotStyle->{Directive[Opacity[0.6]]},PlotPoints->30,AxesLabel->{x,y,z}],ContourPlot3D[y==s,{x,-1,1},{y,0,1},{z,-2,2}]], RegionPlot[-2≤z≤ 2+1&&-(Sqrt[1-(s^2)])≤x≤(Sqrt[1-(s^2)]),{x,-1,1}, {z,-2,2}]}, {"Il piano a quota y","la y-sezione E(y)"}}], {s,0,1}]

Manipulate[Grid[{{Show[RegionPlot3D[-1≤x≤1&&0≤y≤ (Sqrt[1-(x^2)])&&-2≤z≤y+1,{x,-1,1},{y,0,1},{z,-2,2}, PlotStyle->{Directive[Opacity[0.6]]},PlotPoints->30,AxesLabel->{x,y,z}],ContourPlot3D[z==s,{x,-1,1},{y,0,1},{z,-2,2}]], RegionPlot[-1≤x≤ 1+1&&Max[0,s-1]≤y≤(Sqrt[1-(x^2)]),{x,-1,1}, {y,0,1}]}, {"Il piano a quota z","la y-sezione E(z)"}}], {s,-2,2}]

Quest’ultimo esempio racchiude la terza e  la quarta descrizione che non sono altro che descrizioni del dominio come normale rispetto all’asse x o al’asse y.