Esercizio 8.24

Calcolare (∫_D)(e^(Sqrt[(x^2)+(y^2)]))dxdy dove D={(x,y)∈(ℝ^2) : (x^2)+(y^2)≤1}. D è chiaramente il disco unitario centrato in (0,0). Conviene passare a coordinate polari (r,θ).

Manipulate[GraphicsGrid[{{Show[RegionPlot[(x^2)+(y^2)≤1,{x,-1,1},{y,-1,1},AspectRatio->Automatic],ParametricPlot[{R Cos[f],R Sin[f]},{f,0,t}],ParametricPlot[{r Cos[t],r Sin[t]},{r,0,R},PlotRange->{{-1,1},{-1,1}}],ListPlot[{{R Cos[t],R Sin[t]}},PlotRange->{{-1,1},{-1,1}},PlotStyle->{PointSize[0.03]}]],Show[RegionPlot[0≤y≤1&&0≤x≤2 Pi,{x,-0.2,2 Pi+0.4},{y,-0.2,1.2},AspectRatio->Automatic],ParametricPlot[{p,R},{p,0,t}],ListPlot[{{t,R}},PlotRange->{{-0.2,2 Pi+0.4},{-0.2,1.2}},PlotStyle->{PointSize[0.02]}]]}},ImageSize->900],{R,0.0001,1},{t,0.0001,2 π }]

L’integrale cercato si riduce all’integrale della funzione (e^r) su un rettangolo, però la funzione (e^r) è moltiplicata per un opportuno “peso”, cioè r, che è il modulo del determinante della Jacobiana della trasformazione di coordinate. Intuitivamente possiamo pensare a questo peso come quel fattore per cui è moltiplicato l’elemento infinitesimo di area quando si vuole considerare l’area della sua immagine mediante il diffeomorfismo che definisce il cambio di coordinate. Ad esempio:

Manipulate[Grid[{{Show[RegionPlot[(x^2)+(y^2)≤1,{x,-1,1},{y,-1,1},AspectRatio->Automatic,PerformanceGoal->"Quality"],RegionPlot[(s1^2)<=(x^2)+(y^2)≤(((s1+h))^2),{x,-1,1},{y,-1,1},AspectRatio->Automatic,PlotStyle->{Blue,Opacity[0.7]},PerformanceGoal->"Quality"],RegionPlot[(s2^2)<=(x^2)+(y^2)≤(((s2+h))^2),{x,-1,1},{y,-1,1},AspectRatio->Automatic,PlotStyle->{Purple,Opacity[0.7]},PerformanceGoal->"Quality"],ImageSize->400],Show[RegionPlot[0≤y≤1&&0≤x≤2 Pi,{x,-0.2,2 Pi+0.4},{y,-0.2,1.2},AspectRatio->Automatic,PerformanceGoal->"Quality"],RegionPlot[s1≤y≤s1+h&&0≤x≤2 Pi,{x,-0.2,2 Pi+0.4},{y,-0.2,1.2},AspectRatio->Automatic,PlotStyle->{Blue,Opacity[0.7]},PerformanceGoal->"Quality"],RegionPlot[s2≤y≤s2+h&&0≤x≤2 Pi,{x,-0.2,2 Pi+0.4},{y,-0.2,1.2},AspectRatio->Automatic,PlotStyle->{Purple,Opacity[0.7]},PerformanceGoal->"Quality"],ImageSize->400]},{"Area Blue ann."  π ((h^2)+2 h s1) ,"Area Blue sq." 2 π h},{ "Area Purple ann." π ((h^2)+2 h s2),"Area Purple sq."2  π h},{"Area Blue ann."π ((h^2)+2 h s1),"Area Blue sq with weight r"Integrate[y,{x,0,2 Pi},{y,s1,s1+h}]},{ "Area Purple ann."π ((h^2)+2 h s2),"Area Purple sq with weight r"Integrate[y,{x,0,2 Pi},{y,s2,s2+h}]}},ItemSize->30,Frame->All],{s1,0.0001,0.8},{s2,0.0001,0.8 },{h,0,0.2 }]

Calcoliamo l’integrale. Prima scriviamo la formula in (x,y) e poi in (r,θ)

Integrate[Exp[(Sqrt[(x^2)+(y^2)])]*Boole[(x^2)+(y^2)≤1],{x,-1,1},{y,-1,1}]

Non sembra riuscirci. Proviamo un’integrazione numerica, dando sempre l’integrale nelle variabili (x,y) (è un’approssimazione numerica dell’integrale)

NIntegrate[Exp[(Sqrt[(x^2)+(y^2)])]*Boole[(x^2)+(y^2)≤1],{x,-1,1},{y,-1,1}]

Che ci ricorda 2π! Vediamo di scrivere l’integrale dopo il cambio di variabile, ovvero (∫_0^(2π))(∫_0^1)((re)^r)drdθ

Integrate[r Exp[r],{r,0,1},{t,0,2 Pi}]

Esercizio 8.25

Calcolare la misura 2-dimensionale dell’insieme T(a,b,c)={(x,y)∈(ℝ^2):((x^2)/(a^2))+((y^2)/(b^2))≤ (c^2)}, con a,b,c > 0 dati. L’insieme T(a,b,c) è un’ellisse con lunghezze dei semiassi che dipendono dai parametric a,b,c.

Manipulate[RegionPlot[((x^2)/(a^2))+((y^2)/(b^2))≤(c^2),{x,-50,50},{y,-50,50},AspectRatio->Automatic,PerformanceGoal->"Quality"],{a,0.0001,10},{b,0.0001,10},{c,0.0001,10}]

Mediante un’opportuno cambiamento di variabili, l’integrale sull’ellisse può essere ricondotto ad un integrale sul disco unitario.

Manipulate[Show[RegionPlot[((x^2)/(s  (a^2) (c^2)+(1-s)))+(( (y^2))/((1-s) +s (b^2) (c^2)))≤1,{x,-5,5},{y,-5,5},AspectRatio->Automatic,PlotStyle->{Blue},PerformanceGoal->"Quality"],RegionPlot[((x^2)/(a^2))+((y^2)/(b^2))≤(c^2),{x,-5,5},{y,-5,5},AspectRatio->Automatic,PlotStyle->{Cyan,Opacity[0.3]},PerformanceGoal->"Quality"]],{a,0.0001,4},{b,0.0001,4},{c,0.0001,2},{s,0,1}]

Quando cambiamo coordinate e passiamo ad integrare la funzione, scritta nel nuovo sistema di coordinate, sul disco unitario, moltiplichiamo per |Det φ’|, dove φ:D→T(a,b,c) è il diffeomorfismo tra D e T(a,b,c) che rappresenta il cambiamento di coordinate (è la trasformazione rappresentata in modo intuitiva dall’animazione precedente). Questo “peso” che aggiungiamo all’integrale è (abc^2). Di nuovo, in maniera intuitiva, possiamo pensare a questo peso come il fattore per cui dobbiamo moltiplicare l’elemento infinitesimo di area del disco unitario per trovare l’elemento infinitesimo di area corrispondente sull’insieme T(a,b,c).  (si provi a disegnare nel grafico precedente un insieme T(a,b,c) con a,b,c tali che (abc^2)<1 e uno con (abc^2)>1. Si vede che durante la trasformazione φ ogni “piccolo” elemento di area si sta restringendo o dilatando, rispettivamente).

Calcoliamo l’area di T(a,b,c). Scriviamo l’integrale nei due modi : in (x,y)∈T(a,b,c) e con il cambio di coordinate φ(X,Y)=(Xac,Ybc) (=(x,y)), quindi nelle variabili (X,Y)∈D.

Integrate[Boole[((x^2)/((a^2) (c^2)))+((y^2)/((b^2) (c^2)))≤1],{x,-a c,a c},{y,-b c,b c}, Assumptions->{a>0&&b>0&&c>0}]

Integrate[a b (c^2) Boole[(x^2)+(y^2)≤1],{x,-1,1},{y,-1,1}]

Esercizio 8.26

Calcolare (∫_D)(x^2)(y^2)dxdy dove D è la porzione del primo quadrante compresa fra le iperboli xy=1, xy=2 e le rette y=(x/2) e y=2x, servendosi del cambiamento di variabili u=xy, v=(y/x). Disegnamo le quattro curve e la regione compresa tra esse

Show[Plot[{(1/x),(2/x),(x/2),2x},{x,0,3},PlotRange->{0,3},PlotStyle->{{Orange,Thick},{Red,Thick},{Purple,Thick},{Blue,Thick}},AspectRatio->Automatic,AxesLabel->{x,y},PerformanceGoal->"Quality"],RegionPlot[ {(x/2)<y<2 x&&(1/x)<y< (2/x)},{x,0,3},{y,0,3},PerformanceGoal->"Quality"]]

Si mostra che g(x,y)=(xy,(y/x)) (:=(u,v)) è un diffeomorfismo tra D ed il rettangolo [1,2]x[(1/2),2]. Chiameremo l’inversa di g, φ:([1,2]x[(1/2),2])→D. Questo è il diffeomorfismo φ di cui dovremo calcolare la matrice Jacobiana ed il determinante, per poter ricondurre l’integrale su D all’integrale sul quadrato [1,2]x[(1/2),2]. φ può essere intuitivamente rappresentato dalla seguente animazione

Manipulate[Show[ContourPlot[{(x Cos[((π s)/4)]+y Sin[((π s)/4)]-s (y Cos[((π s)/4)]-x Sin[((π s)/4)])) (x Cos[((π s)/4)]+y Sin[((π s)/4)]+s (y Cos[((π s)/4)]-x Sin[((π s)/4)]))==1+s,(-(2-(Sqrt[2])) (1-s)+x Cos[((π s)/4)]+y Sin[((π s)/4)]-s (y Cos[((π s)/4)]-x Sin[((π s)/4)])) (-(2-(Sqrt[2])) (1-s)+x Cos[((π s)/4)]+y Sin[((π s)/4)]+s (y Cos[((π s)/4)]-x Sin[((π s)/4)]))==2 (1-s)+4 s,y-0.5==0.5 s (x-1),y-2==2 s (x-1)},{x,0,3},{y,0,3},AspectRatio->Automatic,ContourStyle->{{Orange,Thick},{Red,Thick},{Blue,Thick},{Purple,Thick}}],RegionPlot[ {  y-0.5≥ 0.5 s (x-1)&&y-2<=2 s (x-1)&&(x Cos[((π s)/4)]+y Sin[((π s)/4)]-s (y Cos[((π s)/4)]-x Sin[((π s)/4)])) (x Cos[((π s)/4)]+y Sin[((π s)/4)]+s (y Cos[((π s)/4)]-x Sin[((π s)/4)]))≥ 1+s&&(-(2-(Sqrt[2])) (1-s)+x Cos[((π s)/4)]+y Sin[((π s)/4)]-s (y Cos[((π s)/4)]-x Sin[((π s)/4)])) (-(2-(Sqrt[2])) (1-s)+x Cos[((π s)/4)]+y Sin[((π s)/4)]+s (y Cos[((π s)/4)]-x Sin[((π s)/4)]))<=2 (1-s)+4 s},{x,0,3},{y,0,3}]],{s,0,1}]

L’integrale (∫_D)(x^2)(y^2)dxdy è uguale a (∫_([1,2]x[(1/2),2]))(u^2)|det φ'(u,v)|dudv. L’inversa φ di g si ricava subito: φ(u,v)=((Sqrt[(u/v)]),(Sqrt[u v]))=(x,y).

FullSimplify[Det[Grad[{(Sqrt[(u/v)]),(Sqrt[u v])},{u,v}]],Assumptions->{u>0&&v>0}]

Per cui (∫_([1,2]x[(1/2),2]))(u^2)|det φ'(u,v)|dudv=(∫_([1,2]x[(1/2),2]))((u^2)/(2v))dudv. Calcoliamo l’integrale nei due sistemi di coordinate

Integrate[(x^2) (y^2) Boole[(x/2)<y<2 x&&(1/x)<y< (2/x)],{x,0,2},{y,0,2}]

Integrate[((u^2)/(2 v)),{u,1,2},{v,(1/2),2}]

Esercizio 7.19

Calcolare (∫_E)(Sqrt[(x^2)-(y^2)])dxdy dove E  è la regione del semipiano x>0 compresa tra le iperboli di equazione (x^2)-(y^2)=1e (x^2)-(y^2)=2 e le rette di equazioni y=px, y=qx con -1<p<q<1. La situazione è simile a quella dell’esercizio precedente. Solo che è “ruotata”di (π/4)in senso orario e le due rette ora hanno pendenze variabili. Disegnamo La regione E al variare di p e q.

Manipulate[Show[ContourPlot[{(x^2)-(y^2)==1,(x^2)-(y^2)==2,y==p x,y==q x},{x,0,3},{y,-3,3},ContourStyle->{{Orange,Thick},{Red,Thick},{Purple,Thick},{Blue,Thick}},AspectRatio->Automatic,AxesLabel->{x,y},PerformanceGoal->"Quality"],RegionPlot[ {p x<y<q x&&(Sqrt[1+(y^2)])<x<(Sqrt[2+(y^2)]) },{x,0,3},{y,-3,3},PerformanceGoal->"Quality"]],{p,-1,0.99},{q,p,0.999}]

A parte queste differenze, la situazione è del tutto analoga a quella dell’esercizio precedente. Ci aspettiamo di trovare un diffeomorfismo tra l’insieme E ed un rettangolo, che stavolta dipenderà dai parametri p e q. Infatti è il diffeomorfismo φ:([1,2]x[p,q])→E definito da φ(u,v)=((Sqrt[(u/(1-(v^2)))]),(Sqrt[((u (v^2))/(1-(v^2)))]))=(x,y). L’inversa, che ci dà le (u,v) in funzione di (x,y) è (u,v)=((x^2)-(y^2),(y/x)). Cerchiamo di rappresentare questo diffeomorfismo in modo intuitivo.

Manipulate[Show[ContourPlot[{(x+s y) (x-s y)==1, (x-(2-(Sqrt[2])) (1-s)+s y) (x-(2-(Sqrt[2])) (1-s)- s y)==2,y-p==p s (x-1),y-q==q s (x-1)},{x,0,3},{y,-3,3},ContourStyle->{{Orange,Thick},{Red,Thick},{Purple,Thick},{Blue,Thick}},AspectRatio->Automatic,AxesLabel->{x,y},PerformanceGoal->"Quality"],RegionPlot[ {p+p s (x-1)<y<q+q s (x-1)&&(x+s y) (x-s y)≥ 1 && (x-(2-(Sqrt[2])) (1-s)+s y) (x-(2-(Sqrt[2])) (1-s)- s y)≤ 2},{x,0,3},{y,-3,3},PerformanceGoal->"Quality"]],{p,-1,0.99},{q,p,0.999},{s,0,1}]

Si calcola |Det φ’(u,v)|. La funzione integranda nel nuovo sistema di coordinate è (Sqrt[(x^2)-(y^2)])=(Sqrt[u]).

FullSimplify[Det[Grad[{(Sqrt[(u/(1-(v^2)))]),(Sqrt[((u (v^2))/(1-(v^2)))])},{u,v}]],Assumptions->{u>0&&v>0}]

Calcoliamo l’integrale nelle nuove variabili (u,v) (L’ integrale nelle variabili (x,y) è difficile anche da scrivere bene!)

Integrate[((Sqrt[u])/(2-2 (v^2))),{u,1,2},{v,p,q}]

Esercizio 7.24

Calcolare (∫_E)(x^2)(y-(x^3))(e^(y+(x^3)))dxdy dove T={(x,y)∈(ℝ^2) : (x^3)≤ y≤ 3 , x≥ 1} usando il cambiamento di variabili u=y-(x^3), v=y+(x^3).

Grid[{{RegionPlot[x≥0&&y≥ 2+x&&y≤6-x,{x,0,3},{y,0,6},AspectRatio->Automatic,PlotPoints->40,ImageSize->180],RegionPlot[(x^3)≤ y≤ 3&&x≥ 1,{x,0.5,2},{y,0,3},AspectRatio->Automatic,PlotPoints->40,ImageSize->180]},{"(φ^(-1))(T)","T"}},ItemSize->20]

Manipulate[Show[ContourPlot[{(x-2 s) Boole[s≤1/2+0.1]+((((x-(1/(1-1/2-0.1))  (1- s)))^3)-( (s/(1/2+0.1))-1)    y) Boole[s≥1/2+0.1]==0,((y-5)/(Tan[(π/4)+s (π/2)]))==-(1-s)  (x-1),(((1-s) (y-3))/(Tan[(π/4)+s (π/2)]))==x-1},{x,-0.0001,3},{y,0,6.5},PerformanceGoal->"Quality",AspectRatio->Automatic,ContourStyle->{{Orange,Thick},{Red,Thick},{Purple,Thick}}],RegionPlot[(x-2 s) Boole[s≤1/2]≥0&&(x-2 s) Boole[1/2≤ s≤1/2+0.1]≤ 0&&((((x-(1/(1-1/2-0.1))  (1- s)))^3)-( (s/(1/2+0.1))-1)    y) Boole[s≥1/2+0.1]≤  0&&(((y-5)/(Tan[(π/4)+s (π/2)]))+(1-s)  (x-1)) Boole[s≤1/2]≤0&&(((y-5)/(Tan[(π/4)+s (π/2)]))+(1-s)  (x-1)) Boole[s≥ 1/2]≥0&&((((1-s) (y-3))/(Tan[(π/4)+s (π/2)]))- x+1) Boole[s≤1/2]≥0&&((((1-s) (y-3))/(Tan[(π/4)+s (π/2)]))- x+1) Boole[s≥ 1/2]≤ 0,{x,-0.0001,3},{y,0,6.5},AspectRatio->Automatic,PerformanceGoal->"Quality"]],{s,0,1}]

Dal cambiamento di variabile u=y-(x^3), v=y+(x^3) ricaviamo il diffeomorfismo inverso φ:(φ^(-1))(T)→T, dove (φ^(-1))(T) è per l’appunto il triangolo in figura su. Si ha x=(((((v-u)/2)))^(1/3)), y=((u+v)/2) . Calcoliamo |Det φ’|. Infine l’integranda nelle nuove variabili (u,v) è (x^2)(y-(x^3))(e^(y+(x^3)))=(((((v-u)/2)))^(2/3)) u (e^v).

FullSimplify[Abs[Det[Grad[{(((((v-u)/2)))^(1/3)),((u+v)/2)},{u,v}]]],Assumptions->{u>0&&v>0&&v>u}]

Calcoliamo l’integrale

Integrate[(x^2) (y-(x^3)) Exp[y+(x^3)] Boole[(x^3)≤y≤3&&x≥1],{x,1,2},{y,1,3}]

FullSimplify[(1/(3 (2^(1/3)) (((-u+v))^(2/3)))) (((((v-u)/2)))^(2/3)) u (E^v)]

Integrate[(((E^v) u)/6) Boole[0≤u≤2&&u+2≤v≤6-u],{u,0,2},{v,2,6}]

Esercizio 8.31

Siano a,b∈ℝ con a<b. E(a,b)={(x,y,z)∈(R^3): (x^2)+(y^2)<(z^2),a<z<b}. Bisogna descrivere E(a,b) al variare di a e b e calcolare (∫_(E(a,b)))(z/(1+(x^2)+(y^2)))dxdydz, (∫_(E(a,b)))(1/(1+(x^2)+(y^2)))dxdydz e (∫_A)(z/(1+3(x^2)+(y^2)))dxdydz dove A={(x,y,z)∈(R^3): 3(x^2)+(y^2)<(((z-2))^2),0<z<1}.

Manipulate[RegionPlot3D[(x^2)+(y^2)≤(z^2)&&a<z<b,{x,-5,5},{y,-5,5},{z,-(Sqrt[2]) 5,(Sqrt[2]) 5},PlotStyle->{Opacity[0.8]},Mesh->None,PlotPoints->35,BoxRatios->Automatic,PerformanceGoal->"Speed"],{a,-(Sqrt[2]) 5,(Sqrt[2]) 5},{b,a+0.2,(Sqrt[2]) 5}]

Si integra per fette parallele al piano xy (le z-sezioni), che sono tutte dei dischi. Per calcolare l’integrale su ogni disco si vede che è conveniente passare a coordinate polari (compare ad esempio (x^2)+(y^2) che in cordinate polari è semplicemente (r^2))

Manipulate[Grid[{{Show[RegionPlot3D[(x^2)+(y^2)≤(z^2)&&a<z<b,{x,-5,5},{y,-5,5},{z,-(Sqrt[2]) 5,(Sqrt[2]) 5},PlotStyle->{Opacity[0.8]},Mesh->None,PlotPoints->20,BoxRatios->Automatic,PerformanceGoal->"Speed"],ContourPlot3D[z==a s,{x,-5,5},{y,-5,5},{z,-(Sqrt[2]) 5,(Sqrt[2]) 5},ContourStyle->{Opacity[0.8]},Mesh->None,BoxRatios->Automatic,PerformanceGoal->"Speed"],ImageSize->400],RegionPlot[(x^2)+(y^2)≤(a^(2 ))(s^2),{x,-5,5},{y,-5,5},ImageSize->400]}}],{a,-(Sqrt[2]) 5,(Sqrt[2]) 5},{b,a+0.2,(Sqrt[2]) 5},{s,1,b/a}]

L’integrale su ogni z-sezione è quindi l’integrale di (1/(1+(x^2)+(y^2))) sul disco D(z) di centro (0,0) e raggio |z|. Passando in coordinate polari x=r Cos(θ), y=r Sin(θ), siccome (x^2)+(y^2)=(r^2)  e Detφ’=r, L’integrale (∫_(D(z)))(1/(1+(x^2)+(y^2)))dxdy diventa (∫_0^(2π))(∫_0^(|z|))(r/(1+(r^2)))drdθ che è semplice da calcolare

Integrate[(r/(1+(r^2))),{r,0,Abs[z]},{t,0,2 Pi}]

Gli integrali (∫_(E(a,b)))(z/(1+(x^2)+(y^2)))dxdydz e (∫_(E(a,b)))(1/(1+(x^2)+(y^2)))dxdydz si riducono rispettivamente a (∫_a^b)πzLog(1+(z^2))dz  e (∫_a^b)πLog(1+(z^2))dz, che si calcolano immediatamente

Integrate[Pi z  Log[1+(z^2)] ,{z,a,b},Assumptions->{a∈Reals&&b∈Reals&&a<b&&a>0}]

Iz[a_,b_]:=(1/2) π ((a^2)-(b^2)-(1+(a^2)) Log[1+(a^2)]+(1+(b^2)) Log[1+(b^2)]);

Integrate[Pi Log[1+(z^2)] ,{z,a,b},Assumptions->{a∈Reals&&b∈Reals&&a<b}]

I0[a_,b_]:=π (2 a-2 b-2 ArcTan[a]+2 ArcTan[b]-a Log[1+(a^2)]+b Log[1+(b^2)]);

L’ultimo integrale ha una forma simile a quelli appena calcolati ed anche la regione A di integrazione ricorda uno degli insiemi E(a,b) per dei particolari a,b. Disegnamo A.

RegionPlot3D[3 (x^2)+(y^2)≤(((z-2))^2)&&0<z<1,{x,-(Sqrt[(4/3)]),(Sqrt[(4/3)])},{y,-(Sqrt[4]),(Sqrt[4])},{z,0,1},PlotStyle->{Red,Opacity[0.5]},Mesh->None,PlotPoints->40,BoxRatios->Automatic]

Manipulate[Show[ContourPlot3D[{z==a+2 t},{x,-4,4},{y,-4,4},{z,-4,4},ContourStyle->{Opacity[0.6]},Mesh->None,BoxRatios->Automatic,PlotPoints->5],ContourPlot3D[{z==b+2 t},{x,-4,4},{y,-4,4},{z,-4,4},Mesh->None,BoxRatios->Automatic,ContourStyle->{Opacity[0.6]},PlotPoints->5],ContourPlot3D[{(((1+2 s))^2)((x )^2)+(y^2)==(((z-2 t))^2)},{x,-4,4},{y,-4,4},{z,-4,4},ContourStyle->{Opacity[0.8]},Mesh->None,BoxRatios->Automatic,PerformanceGoal->"Speed",PlotPoints->13],ContourPlot3D[{3 (x^2)+(y^2)==(((z-2))^2),z==0,z=1},{x,-2,2},{y,-4,4},{z,-4,4},RegionFunction->Function[{x,y,z},0<z<1&&3 (x^2)+(y^2)≤4],ContourStyle->{Red},Mesh->None,PlotPoints->40,BoxRatios->Automatic,PerformanceGoal->"Speed"],ImageSize->500],{s,0,1},{t,0,1},{a,-4,4},{b,-4,4}]

Con un’omotetia (contrazione delle x, in questo caso) ed una traslazione abbiamo visto che A è diffeomorfo ad uno degli E(a,b), in particolare E(-2,-1). Partendo da E(-2,-1) (chiamiamo X,Y,Z le coordinate in cui descriviamo E(-2,-1), mentre (x,y,z)=φ(X,Y,Z) quelle in cui abbiamo descritto A) il diffeomorfismo φ può essere descritto così: lascia le Y invariate: y=Y. Contrae le X di un fattore (Sqrt[3]), cioè x=(X/(Sqrt[3])). Trasla le Z di 2 (“verso l’alto”) ovvero z=Z+2. Quindi φ(X,Y,Z)=(X/(Sqrt[3]),Y,Z+2)=(x,y,z). L’integranda (z/(1+3(x^2)+(y^2))) nelle coordinate (X,Y,Z) diventa ((Z+2)/(1+(X^2)+(Y^2))). Esso è moltiplicato per |Detφ’| e integrato in E(-2,-1). |Detφ’| è una costante (capita nel caso di omotetie e traslazioni) che troveremo tra poco (è dato dall’omotetia in X, sarà (1/(Sqrt[3])). E dai due integrali precedenti (sostituendo a =-2 e b=-1) sappiamo questo integrale quanto vale

FullSimplify[Abs[Det[Grad[{X/(Sqrt[3]),Y,Z+2},{X,Y,Z}]]],Assumptions->{X∈Reals&&Y∈Reals&&Z∈Reals}]

(1/(Sqrt[3]))(Iz[-2,-1]+2I0[-2,1])

Esercizio 8.42

Disegnare il solido D={(x,y,z)∈(R^3): (1/2)≤ (x^2)+(y^2)≤ 4,x≤0,y≥0,z≥0} e calcolare l’integrale triplo (∫_D)((Log(2(x^2)+2(y^2)+2(z^2)))/(Sqrt[(x^2)+(y^2)+(z^2)]))dxdydz. Il solido è la regione contenuta tra le due sfere di centro (0,0,0) e raggi (1/(Sqrt[2]))e 2 e che si trova nell’ottante x≤0,y≥0,z≥0. Vediamo che nell’integranda compaiono le quantità (x^2)+(y^2)+(z^2) che in coordinate sferiche sono semplicemente (r^2). Inoltre D è una parte di una sfera e si presta ad essere descritta facilmente in coordinate sferiche (r,ϕ,θ). Ricordiamo cosa rappresentano queste variabili.

Manipulate[Show[ContourPlot3D[z==0,{x,-1,1},{y,-1,1},{z,-1,1},RegionFunction->Function[{x,y,z},(x^2)+(y^2)≤(R^2)],Mesh->None,ContourStyle->{Opacity[0.3]},PerformanceGoal->"Quality"],ContourPlot3D[z==0,{x,-1,1},{y,-1,1},{z,-1,1},RegionFunction->Function[{x,y,z},(x^2)+(y^2)≥ (R^2)],ContourStyle->{Opacity[0.2]},PerformanceGoal->"Quality"],ContourPlot3D[{x==0,y==0},{x,-1,1},{y,-1,1},{z,-1,1},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ContourPlot3D[{z==0,y==0},{x,-1,1},{y,-1,1},{z,-1,1},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ContourPlot3D[{z==0,x==0},{x,-1,1},{y,-1,1},{z,-1,1},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ContourPlot3D[y Cos[t]==x Sin[t],{x,-1,1},{y,-1,1},{z,-1,1},RegionFunction->Function[{x,y,z},(x^2)+(y^2)+(z^2)≤(R^2)&&x Cos[t]+y Sin[t]≥ 0],Mesh->None,ContourStyle->{Opacity[0.3]},PerformanceGoal->"Quality"],ParametricPlot3D[{r Sin[f] Cos[t],r Sin[f] Sin[t],r Cos[f] },{r,0,R},PerformanceGoal->"Quality"],ListPointPlot3D[{{R Sin[f] Cos[t],R Sin[f] Sin[t],R Cos[f] }},PlotStyle->PointSize[.02]],ParametricPlot3D[{r Cos[s],r Sin[s],0},{r,0,R},{s,0,t},Mesh->None,PlotStyle->{Blue,Opacity[1]},PerformanceGoal->"Quality"],ParametricPlot3D[{r Sin[s] Cos[t],r Sin[s] Sin[t],r Cos[s]},{r,0,R},{s,0,f},Mesh->None,PlotStyle->{Red,Opacity[1]},PerformanceGoal->"Quality"],ParametricPlot3D[{q  Cos[t],q  Sin[t],R Cos[f]},{q,0,R Sin[f]},PlotStyle->{Orange,Tube[0.006]}],ParametricPlot3D[{R Sin[f] Cos[t],R Sin[f] Sin[t],q },{q,0,R Cos[f]},PlotStyle->{Orange,Tube[0.006]}],ParametricPlot3D[{q Cos[t],R Sin[f] Sin[t],0 },{q,0,R Sin[f]},PlotStyle->{Orange,Tube[0.006]}],ParametricPlot3D[{R Sin[f]  Cos[t],q  Sin[t],0},{q,0,R Sin[f]},PlotStyle->{Orange,Tube[0.006]}],ImageSize->500,AxesLabel->{X,Y,Z}],{R,0.00001,1},{f,0.00001,Pi},{t,0.00001,2 Pi}]

Disegnamo D

RegionPlot3D[1/2≤(x^2)+(y^2)+(z^2)≤4 && x≤0&&z≥0&&y≥0,{x,-2,0},{y,0,2},{z,0,2},Mesh->None,PlotPoints->30,BoxRatios->Automatic,PlotStyle->Opacity[0.6],AxesLabel->{X,Y,Z}]

Si vede che D può essere descritto bene in coordinate radiali (r,ϕ,θ). r rappresenta la distanza dall’origine di (x,y,z). Per i punti in D essa è (1/(Sqrt[2]))≤ r≤ 2. L’angolo ϕ è l’angolo formato con l’asse z ( a partire dalla semiretta z>0). Vediamo quindi che 0≤ ϕ≤ (π/2). Infine θ è l’angolo formato sul piano xy con l’asse x (a  partire dalla semiretta x>0). Siccome sul piano xy consideriamo  x≤0 e y≥0, allora (π/2)≤ θ≤ π.

Manipulate[Show[RegionPlot3D[1/2≤(x^2)+(y^2)+(z^2)≤4 && x≤0&&z≥0&&y≥0,{x,-2,0.5},{y,0,2},{z,0,2},Mesh->None,PlotPoints->15,BoxRatios->Automatic,PlotStyle->Opacity[0.6],AxesLabel->{X,Y,Z}],ParametricPlot3D[{r Sin[f] Cos[t],r Sin[f] Sin[t],r Cos[f] },{r,0,R},PlotStyle->{Blue,Tube[0.006]}],ListPointPlot3D[{{R Sin[f] Cos[t],R Sin[f] Sin[t],R Cos[f] }},PlotStyle->PointSize[.02]],ContourPlot3D[{x==0,y==0},{x,-2,0.5},{y,0,2},{z,0,2},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ContourPlot3D[{z==0,y==0},{x,-2,0.5},{y,0,2},{z,0,2},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ContourPlot3D[{z==0,x==0},{x,-2,0.5},{y,0,2},{z,0,2},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ImageSize->500],{R,(1/(Sqrt[2])),2},{f,0,(π/2)},{t,(π/2),π}]

Ricordiamo qual era il cambio di variabile (x,y,z)=φ(r,ϕ,θ)=( r Sin(ϕ) Cos(θ) , r Sin(ϕ) Sin(θ) , r Cos(ϕ) ). Ricordiamo che |Detφ'|=(r^2)Sin(ϕ). L’integrale diventa (∫_0^(π/2))(∫_(π/2)^π)(∫_(1/(Sqrt[2]))^2)((Log(2 (r^2)))/r)(r^2)Sin(ϕ)drdθdϕ. Calcoliamolo

Clear[x,y,z]

Integrate[((Log[2 ((x^2)+(y^2)+(z^2))])/(Sqrt[(x^2)+(y^2)+(z^2)]))  Boole[1/2≤(x^2)+(y^2)+(z^2)≤4 ],{x,-2,0},{y,0,2},{z,0,2}]

Proviamo con un’integrazione numerica. Pare non riuscire ad integrare con la funzione e il dominio dati in questa forma.

NIntegrate[((Log[2 ((x^2)+(y^2)+(z^2))])/(Sqrt[(x^2)+(y^2)+(z^2)]))  Boole[1/2≤(x^2)+(y^2)+(z^2)≤4 ],{x,-2,0},{y,0,2},{z,0,2}]

Integriamo nelle nuove coordinate. Troviamo la formula esatta dell’integrale e diamone una stima approssimata per vedere se coincide con quella trovata su

Integrate[Log[2 (r^2)] r Sin[f],{r,1/(Sqrt[2]),2},{f,0,Pi/2},{t,Pi/2,Pi}]

N[π (-(7/8)+Log[8])]

Esercizio 7.34

Per ogni h>0 sia (Subscript[E, h])={(x,y)∈(R^2): 0≤x≤h ,0≤ y≤ (x/(1+(x^2)))}. Disegnare (Subscript[E, h]), calcolarne l’area. Trovare l’ordinata (Subscript[y, h])  del baricentro di (Subscript[E, h]). Calcolare il volume del solido (Subscript[S, h]) ottenuto facendo ruotare (Subscript[E, h]) attorno all’asse x.

Manipulate[RegionPlot[0≤ x≤ h&&0≤ y≤ (x/(1+(x^2))),{x,0,5},{y,0,1.3},PlotPoints->60,AspectRatio->Automatic,ImageSize->500],{h,0,5}]

L’area (Subscript[A, h])  è data dalla formula ((Log(1+(h^2)))/2) (il dominio è scritto in forma normale rispetto alle x, il calcolo dell’area è immediato.

Integrate[ (x/(1+(x^2))),{x,0,h}]

Ah[h_]:=(1/2) Log[1+(h^2)]

Le coordinate del baricentro ((Subscript[x, h]),(Subscript[y, h])) sono date da ((((∫_(Subscript[E, h]))xdxdy)/(Subscript[A, h])),(((∫_(Subscript[E, h]))xdxdy)/(Subscript[A, h]))).

Integrate[x Boole[0≤ y≤ (x/(1+(x^2)))],{x,0,h},{y,0,1},Assumptions->{h∈Reals,h>0}]

Xh[h_]:=((h-ArcTan[h])/((1/2) Log[1+(h^2)]));

Integrate[y Boole[0≤ y≤ (x/(1+(x^2)))],{x,0,h},{y,0,1},Assumptions->{h∈Reals,h>0}]

Yh[h_]:=((-h+ArcTan[h]+(h^2) ArcTan[h])/(4 (1+(h^2)) (1/2) Log[1+(h^2)]));

Manipulate[Show[RegionPlot[0≤ x≤ h&&0≤ y≤ (x/(1+(x^2))),{x,0,4},{y,0,1.3},PlotPoints->60,AspectRatio->Automatic,ImageSize->500],ListPlot[{{Xh[h],Yh[h]}},PlotStyle->{Red,PointSize[0.01]}]],{h,0.00001,4}]

Manipulate[Show[ParametricPlot3D[{u,r Cos[t],r Sin[t]},{u,0,h},{r,0,(u/(1+(u^2)))},PlotRange->{{-0.2,4},{-1.3,1.3},{-1.3,1.3}},Mesh->None,PlotStyle->{Opacity[0.8]}],ListPointPlot3D[{{Xh[h],Yh[h] Cos[t],Sin[t] Yh[h]}},PlotStyle->{PointSize[0.02]}],ParametricPlot3D[{Xh[h],Yh[h] Cos[s],Sin[s] Yh[h]},{s,0,t}],ContourPlot3D[{z==0,y==0},{x,-0.2,4},{y,-1.3,1.3},{z,-1.3,1.3},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ContourPlot3D[{x==0,y==0},{x,-0.2,4},{y,-1.3,1.3},{z,-1.3,1.3},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ContourPlot3D[{z==0,x==0},{x,-0.2,4},{y,-1.3,1.3},{z,-1.3,1.3},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.008],Opacity[0.5]}}}],ParametricPlot3D[{u,(u/(1+(u^2))) Cos[f],(u/(1+(u^2))) Sin[f]},{u,0,h},{f,0,t},PlotRange->{{-0.2,4},{-1.3,1.3},{-1.3,1.3}},Mesh->None,PlotStyle->{Opacity[0.6]}],AspectRatio->Automatic,ImageSize->500,AxesLabel->{X,Y,Z}],{h,0.1,4},{t,0.0001,2 Pi}]

Calcoliamo il volume. Per il Teorema di Guldino, Vol((Subscript[S, h]))=2(Subscript[πy, h])(Subscript[A, h])

Volh[h_]:=2 Pi Yh[h] Ah[h]

Volh[h]

Clear[x,y,z]

Vediamo il solido ottenuto ruotando la stessa figura, ma traslata (sul piano xy) di 2 in y (cioè y+2).

Integrate[x Boole[2≤ y≤2+ (x/(1+(x^2)))],{x,0,h},{y,2,3},Assumptions->{h∈Reals,h>0}]

Integrate[y Boole[2≤ y≤2+ (x/(1+(x^2)))],{x,0,h},{y,2,3},Assumptions->{h∈Reals,h>0}]

X2h[h_]:=((h-ArcTan[h])/(Ah[h]))

Y2h[h_]:=(((-h+ArcTan[h]+(h^2) ArcTan[h]+4 Log[1+(h^2)]+4 (h^2) Log[1+(h^2)])/(4 (1+(h^2))))/(Ah[h]))

Manipulate[Show[RegionPlot[0≤ x≤ h&&2≤ y≤2+ (x/(1+(x^2))),{x,0,4},{y,0,3.3},PlotPoints->60,AspectRatio->Automatic,ImageSize->500],ListPlot[{{X2h[h],Y2h[h]}},PlotStyle->{Red,PointSize[0.01]}]],{h,0.00001,4}]

Manipulate[Show[ParametricPlot3D[{u,r Cos[t],r Sin[t]},{u,0,h},{r,2,2+(u/(1+(u^2)))},PlotRange->{{-0.2,4},{-3.3,3.3},{-3.3,3.3}},Mesh->None,PlotStyle->{Opacity[0.8]}],ListPointPlot3D[{{X2h[h],Y2h[h] Cos[t],Sin[t] Y2h[h]}},PlotStyle->{PointSize[0.02]}],ParametricPlot3D[{X2h[h],Y2h[h] Cos[s],Sin[s] Y2h[h]},{s,0,t}],ContourPlot3D[{z==0,y==0},{x,-0.2,4},{y,-1.3,1.3},{z,-3.3,3.3},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.01],Opacity[0.5]}}}],ContourPlot3D[{x==0,y==0},{x,-0.2,4},{y,-3.3,3.3},{z,-3.3,3.3},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.01],Opacity[0.5]}}}],ContourPlot3D[{z==0,x==0},{x,-0.2,4},{y,-3.3,3.3},{z,-3.3,3.3},Contours->{0},ContourStyle->Opacity[0],Mesh->None,BoundaryStyle->{1->None,2->None,{1,2}->{{Black,Tube[0.01],Opacity[0.5]}}}],ParametricPlot3D[{u,(2+(u/(1+(u^2)))) Cos[f],(2+(u/(1+(u^2))))  Sin[f]},{u,0,h},{f,0,t},PlotRange->{{-0.2,4},{-3.3,3.3},{-3.3,3.3}},Mesh->None,PlotStyle->{Opacity[0.6]}],ParametricPlot3D[{u,2  Cos[f],2   Sin[f]},{u,0,h},{f,0,t},PlotRange->{{-0.2,4},{-3.3,3.3},{-3.3,3.3}},Mesh->None,PlotStyle->{Opacity[0.6]}],ParametricPlot3D[{u,r Cos[t],r Sin[t]},{u,0,h},{r,0,(u/(1+(u^2)))},PlotRange->{{-0.2,4},{-1.3,1.3},{-1.3,1.3}},Mesh->None,PlotStyle->{Opacity[0.8]}],ListPointPlot3D[{{Xh[h],Yh[h] Cos[t],Sin[t] Yh[h]}},PlotStyle->{PointSize[0.02]}],ParametricPlot3D[{Xh[h],Yh[h] Cos[s],Sin[s] Yh[h]},{s,0,t}],ParametricPlot3D[{u,(u/(1+(u^2))) Cos[f],(u/(1+(u^2))) Sin[f]},{u,0,h},{f,0,t},PlotRange->{{-0.2,4},{-1.3,1.3},{-1.3,1.3}},Mesh->None,PlotStyle->{Opacity[0.6]}],AspectRatio->Automatic,ImageSize->500,AxesLabel->{X,Y,Z}],{h,0.1,4},{t,0.0001,2 Pi}]

Le figure che facciamo ruotare sono le stesse, ma il volume è chiaramente diverso. E dipende appunto dalla distanza del baricentro (dove immaginiamo “concentrata” tutta la massa (o l’ “area”, per così dire) della figura. Vediamo la formula del volume del secondo solido ottenuto

Vol2h[h_]:=2 Pi Y2h[h] Ah[h]

Vol2h[h]

FullSimplify[Vol2h[h]/Volh[h]]

Rapp[h_]:=1+((4 (1+(h^2)) Log[1+(h^2)])/(-h+(1+(h^2)) ArcTan[h]))

Plot[Rapp[h],{h,0,10},PlotRange->{0,30}]

Limit[Rapp[h],h->+Infinity]

FullSimplify[Rapp'[h]]

FindRoot[Rapp'[h]==0,{h,1}]

Rapp[1.6495381447470492`]

Questa analisi un po’ approssimata di dice già che il volume del solido ottenuto traslando la figura a distanza 2 dall’asse di rotazione è almeno 10 volte più grande del  volume del solido (Subscript[S, h]).  Questo rapporto va a +∞ per h che va a 0 o a +∞.