Soluzioni I compitino Analisi 2

Esercizio 1

Scriviamo la matrice A

A={{-3,-4},{1,1}};

MatrixForm[A]

Vediamo qual è il polinomio caratteristico di A

Factor[CharacteristicPolynomial[A,x]]

A ha un autovalore doppio che è λ=-1. Per Hamilton-Cayley la matrice A soddisfa la sua equazione caratteristica: (((𝕀+A))^2)=𝕆:

MatrixForm[MatrixPower[IdentityMatrix[2]+A,2]]

Pertanto la matrice esponenziale (e^At)=(e^(-𝕀t))(e^((𝕀+A)t)). Calcoliamola direttamente con Mathematica:

MatrixForm[MatrixExp[t A]]

Esercizio 2

M={(x,y,z)∈(ℝ^3):0<(x^2)+(y^2)<4 , z=(Sqrt[(x^2)+(y^2)])}. M è varietà:  esso è la superficie della porzione di cono (z^2)=(x^2)+(y^2) la cui altezza z è compresa tra 0 e 2. Il punto (0,0,0) non è in M (infatti abbiamo disuguaglianze strette). Neppure il “bordo superiore” di questa superficie, ovvero (x^2)+(y^2)=4 , z=2 è compreso, sempre perchè le disuguaglianze sono strette. In ogni altro punto, M è rappresentato localmente come vincolo (zeri di una funzione sommersiva, z-(Sqrt[(x^2)+(y^2)])), ma anche come grafico di una funzione immersiva (x,y,(Sqrt[(x^2)+(y^2)])). Nell’immagine verranno evidenziati i “bordi” di cui si parlava, che non fanno però parte di M.

punto2=ListPointPlot3D[{{0,0,0}},PlotStyle->{PointSize[.02]},ColorFunction->Function[{x,y,z},RGBColor[x+0.8,y,z]]];

curva21=ParametricPlot3D[{2 Cos[t],2 Sin[t],2},{t,0,2 Pi},Mesh->None,ColorFunctionScaling->False,PlotStyle->{Red,Tube[.03]},AxesLabel->{x,y,z}];

M2=Plot3D[(Sqrt[(x^2)+(y^2)]),{x,-2,2},{y,-2,2},RegionFunction->Function[{x,y,z},0<(x^2)+(y^2)<4],AxesLabel->{x,y,z},Mesh->None,PlotStyle->Opacity[0.6]];

Show[punto2,curva21,M2,PlotRange->All,BoxRatios->Automatic,ImageSize->400]

Determiniamo lo spazio vettoriale normale ad M nel punto (1,1,(Sqrt[2])). Tale punto è sulla varietà. Localmente attorno a (1,1(Sqrt[2])) M è rappresentata come zeri di g(x,y,z)=z-(Sqrt[(x^2)+(y^2)]). Lo spazio vettoriale tangente a M nel punto considerato è Ker Dg(1,1,(Sqrt[2])).

g[x_,y_,z_]:=z-(Sqrt[(x^2)+(y^2)]);

Grad[g[x,y,z],{x,y,z}]/.{x->1,y->1,z->(Sqrt[2])}

Lo spazio vettoriale tangente ad M in (1,1,(Sqrt[2])) è determinato dall’equazione determinato dall’equazione -(1/(Sqrt[2]))x-(1/(Sqrt[2]))y+z=0. E’ perpendicolare al vettore (-(1/(Sqrt[2])),-(1/(Sqrt[2])),1) (che quindi dà la direzione dello spazio normale, che sarà una retta). Lo spazio affine tangente ad M nel punto considerato ha equazione  -(1/(Sqrt[2]))(x-1)-(1/(Sqrt[2]))(y-1)+(z-(Sqrt[2]))=0 (è il piano tangente ad M nel punto) . Disegnamolo.

t2=ContourPlot3D[-(1/(Sqrt[2])) (x+y-2)+z-(Sqrt[2])==0,{x,-3,3},{y,-3,3},{z,-1,3},Mesh->None,ContourStyle->Opacity[0.7]];

pp2=ListPointPlot3D[{{1,1,(Sqrt[2])}},PlotStyle->{PointSize[.015]},BoxRatios->Automatic];

Show[M2,t2,pp2,PlotRange->All,BoxRatios->Automatic,ImageSize->500]

Come abbiamo detto, lo spazio normale è una retta, che è perpendicolare al piano tangente. Essa dunque è parallela al vettore (-(1/(Sqrt[2])),-(1/(Sqrt[2])),1). Per trovare le equazioni che descrivono la retta (siamo in (ℝ^3) quindi una retta è descritta da due equazioni) cerchiamo due vettori ortogonali a (-(1/(Sqrt[2])),-(1/(Sqrt[2])),1) (e tra loro ortogonali, insomma, completiamo una base di (ℝ^3)). Essi sono (1,-1,0) e (((Sqrt[2])/2),((Sqrt[2])/2),1). Quindi lo spazio vettoriale normale avrà equazioni x-y=0 e ((Sqrt[2])/2)(x+y)+z=0. Lo spazio affine (la retta normale passante per il punto  (1,1,(Sqrt[2])) ) avrà equazioni (x-1)-(y-1)=0 e x+y+(2/(Sqrt[2]))z-4=0. Disegnamola

r2=ContourPlot3D[{x==y,x+y+(2/(Sqrt[2])) z-4==0},{x,-2,2},{y,-2,2},{z,0,2},Mesh->None,Contours->{0},ContourStyle->Opacity[0],ColorFunctionScaling->False,BoundaryStyle->{1->None,2->None,{1,2}->{{Tube[.02]}}},AxesLabel->{x,y,z}];

Show[M2,r2,pp2,PlotRange->All,BoxRatios->{1,1,0.5}]

Dobbiamo determinare i massimi e i minimi assoluti di f(x,y)=(x^2)-(y^2)+(((z-1))^2) sull’insieme Ω={(x,y,z)∈(ℝ^3) : (Sqrt[(x^2)+(y^2)])≤z≤2}. Questa regione chiusa e limitata (quindi è compatta) è delimitata dalla chiusura di M (la varietà appena studiata. La sua chiusura comprende il punto (0,0,0) e il bordo superiore, cioè la circonferenza in x ed y di centro (0,0) e raggio 2 che si trova a quota z=2) e il piano z=2. Disegnamo questa regione

R2=RegionPlot3D[(Sqrt[(x^2)+(y^2)])≤z≤2,{x,-2.5,2.5},{y,-2.5,2.5},{z,-0.5,2.5},PlotStyle->{Opacity[0.8]},Mesh->None,PlotPoints->60,AxesLabel->{x,y,z},BoxRatios->Automatic]

Essendo f continua ed Ω compatto, esisteranno massimi e minimi assoluti per f su Ω. Essi possono essere punti interni di Ω, o punti sul bordo di Ω. Il bordo di Ω non ha una descrizione unica. Esso è composto da più parti: da più varietà! Dobbiamo individuarle tutte e studiare i massimi e minimi vincolati per f su queste varietà. Iniziamo comunque coi punti interni. Cerchiamo punti in Ω dove il gradiente si annulla.

f[x_,y_,z_]:=(x^2)-(y^2)+(((z-1))^2);

Grad[f[x,y,z],{x,y,z}]

Esso è nullo nel punto (0,0,1) che è un punto della nostra regione Ω. Il bordo di Ω è composto da M (la superficie del cono, escluso il punto (0,0,0) e il bordo superiore), dal disco  D=((x^2)+(y^2)< 4, z=2) (anche questa è una varietà 2-dimensionale come M) , dalla curva Γ=((x^2)+(y^2)= 4, z=2) che è una varietà unidimensionale (è l’intersezione tra il piano z=2 e la porzione superiore di cono z=(Sqrt[(x^2)+(y^2)])) e infine dal punto V=(0,0,0). Quindi dobbiamo cercare i massimi vincolati su queste diverse varietà (che hanno anche diverse dimensioni: ne abbiamo due di dimensione due, ovvero superfici; una di dimensione uno, una curva; e una di “dimensione 0”, il punto) Intanto disegnamole

disco2=ContourPlot3D[z==2,{x,-2,2},{y,-2,2},{z,1.5,2.1},RegionFunction->Function[{x,y,z},0<(x^2)+(y^2)<4],Mesh->None,ContourStyle->Opacity[0.6]];

GraphicsGrid[{{R2,M2,disco2,curva21,punto2},{"La regione interna","la varietà M","il disco D","la curva Γ","Il punto P"}},ImageSize->1200]

Mettendo tutto sullo stesso grafico, per visualizzare meglio, ecco come abbiamo suddiviso la nostra regione Ω.

shell0=RegionPlot3D[(Sqrt[(x^2)+(y^2)])≤z≤2,{x,-2.5,2.5},{y,-2.5,2.5},{z,-0.5,2.5},PlotStyle->{Red,Opacity[0.9]},Mesh->None,PlotPoints->60,AxesLabel->{x,y,z},BoxRatios->Automatic];

shell1=Plot3D[(Sqrt[(x^2)+(y^2)])-0.5,{x,-2,2},{y,-2,2},RegionFunction->Function[{x,y,z},0<(x^2)+(y^2)<4],AxesLabel->{x,y,z},Mesh->None,PlotStyle->{Red,Opacity[0.7]}];

shell2=ContourPlot3D[z==2.5,{x,-2,2},{y,-2,2},{z,1.5,2.6},RegionFunction->Function[{x,y,z},0<(x^2)+(y^2)<4],Mesh->None,ContourStyle->{Red,Opacity[0.8]}];

shell3=ParametricPlot3D[{2 Cos[t],2 Sin[t],2.25},{t,0,2 Pi},Mesh->None,ColorFunctionScaling->False,PlotStyle->{Red,Tube[.03]},AxesLabel->{x,y,z}];

shell4=ListPointPlot3D[{{0,0,-0.75}},PlotStyle->{PointSize[.02]},ColorFunction->Function[{x,y,z},RGBColor[x+0.8,y,z]]];

Show[shell0,shell1,shell2,shell3,shell4,PlotRange->All,BoxRatios->Automatic,ImageSize->400]

Cerchiamo punti critici su M. M è data localmente dagli zeri di g. Applichiamo il Teorema dei Moltiplicatori di Lagrange. Se un punto (x,y,z) è critico llora ∇f(x,y,z) e ∇g(x,y,z) devono essere linearmente dipendenti. In più (x,y,z)∈M. Questo porta a risolvere il seguente sistema

Solve[((x y)/(Sqrt[(x^2)+(y^2)]))==0&&y (-1+((z-1)/(Sqrt[(x^2)+(y^2)])))==0&&x (1+((z-1)/(Sqrt[(x^2)+(y^2)])))==0&&z== (Sqrt[(x^2)+(y^2)]),{x,y,z}]

Punti critici su M sono (±(1/2),0,(1/2)). Passiamo al disco D. Esso è dato dall’equazione z=2. Cerchiamo punti critici di f ristretta a questo piano: f(x,y,2)=(x^2)-(y^2)+1. Essa è una funzione di due variabili. Cerchiamo punti critici imponendo che il gradiente di questa funzione di due variabili si annulli (in questo caso, è più veloce che col metodo dei moltiplicatori). Chiaramente poi dobbiamo vedere se gli eventuali punti critici che troviamo sono tali che (x^2)+(y^2)≤ 4, cioè se sono nel disco (poichè stiamo ricercando in questo modo punti critici su tutto z=2).

f2[x_,y_]:=(x^2)-(y^2)+1;

Grad[f2[x,y],{x,y}]

Il gradiente si annulla per x=0, y=0. Siccome stiamo sul piano z=0 il punto è (0,0,2) che è in D. Passiamo ora a considerare la curva Γ. Essa è una varietà unidimensionale. Essa è data come zeri di una funzione h:(ℝ^3)->(ℝ^2), h(x,y,z)=((Subscript[h, 1])(x,y,z), (Subscript[h, 2])(x,y,z)), dove (Subscript[h, 1])(x,y,z)=z-(Sqrt[(x^2)+(y^2)]), (Subscript[h, 2])(x,y,z)=z-2. Infatti la curva Γ soddisfa le equazioni z=2 e z=(Sqrt[(x^2)+(y^2)]).  Per trovare punti critici vincolati su Γ dobbiamo imporre che ∇f(x,y,z), ∇(Subscript[h, 1])(x,y,z) e ∇(Subscript[h, 2])(x,y,z) siano linearmente dipendenti e che (x,y,z) sia su Γ. Questo porta al sistema

Solve[x y ==0&&(x^2)+(y^2)== 4&&z==2,{x,y,z}]

Abbiamo quattro punti: (0,±2,2) e (±2,0,2). Infine ci resta la varietà di dimensione 0, cioè il punto (0,0,0) dove vedremo quanto vale la funzione. Disegnamo tutti i punti critici che abbiamo trovato.

critici=ListPointPlot3D[{{0,0,0},{0,2,2},{0,-2,2},{2,0,2},{-2,0,2},{0,0,2},{1/2,0,1/2},{-1/2,0,1/2},{0,0,1}},PlotStyle->{PointSize[.02]},ColorFunction->Function[{x,y,z},RGBColor[0.8,0,0.3]]];

reg2=RegionPlot3D[(Sqrt[(x^2)+(y^2)])≤z≤2,{x,-2.5,2.5},{y,-2.5,2.5},{z,-0.5,2.5},PlotStyle->{Opacity[0.5]},Mesh->None,PlotPoints->60,AxesLabel->{x,y,z},BoxRatios->Automatic];

Show[reg2,critici,BoxRatios->Automatic,ImageSize->400]

Ora che abbiamo determinato tutti i punti critici, calcoliamo f in questi punti. I massimi e minimi assoluti saranno sicuramente tra questi punti.

{f[0,0,0],f[0,2,2],f[0,-2,2],f[2,0,2],f[-2,0,2],f[0,0,2],f[1/2,0,1/2],f[-1/2,0,1/2],f[0,0,1]}

Il minimo assoluto è -3 e viene raggiunto in (0,±2,2). Il massimo assoluto è 5 e viene raggiunto in (±2,0,2). Gli altri sono punti critici non di massimo o minimo assoluti. “Disegnamo” la funzione f sul bordo di Ω come gradiente di colore.

RegionPlot3D[(Sqrt[(x^2)+(y^2)])≤z≤2,{x,-2,2},{y,-2,2},{z,0,2},Mesh->None,PlotPoints->60,AxesLabel->{x,y,z},BoxRatios->Automatic,ColorFunction->Function[{x,y,z}, Hue[((x^2)-(y^2)+(((1-z))^2))/15]],ColorFunctionScaling->False]

Mathematica può cercare i massimi e minimi assoluti immediatamente. Vediamo se il nostro risultato è giusto (Mathematica ne trova uno per volta se ce ne sono più di uno. Iteriamo il processo fornendo ad ogni passo il vincolo che il massimo non sia quello trovato in precedenza. Finchè non ci fermiamo)

Maximize[{(x^2)-(y^2)+(((z-1))^2),(Sqrt[(x^2)+(y^2)])≤z≤2},{x,y,z}]

Maximize[{(x^2)-(y^2)+(((z-1))^2),(Sqrt[(x^2)+(y^2)])≤z≤2&&x≠-2},{x,y,z}]

Maximize[{(x^2)-(y^2)+(((z-1))^2),(Sqrt[(x^2)+(y^2)])≤z≤2&&x≠-2&&x≠2},{x,y,z}]

Minimize[{(x^2)-(y^2)+(((z-1))^2),(Sqrt[(x^2)+(y^2)])≤z≤2},{x,y,z}]

Minimize[{(x^2)-(y^2)+(((z-1))^2),(Sqrt[(x^2)+(y^2)])≤z≤2&&y≠-2},{x,y,z}]

Minimize[{(x^2)-(y^2)+(((z-1))^2),(Sqrt[(x^2)+(y^2)])≤z≤2&&y≠-2&&y≠2},{x,y,z}]

Esercizio 3

Dobbiamo calcolare (∫_E)(x^2)dxdydz, dove E={(x,y,z)∈(ℝ^3) : (x^2)+(y^2)≤ 1 , (x^2)+(z^2)≤1}. E è la regione compresa tra due cilindri, ovvero il cilindro (x^2)+(y^2)≤ 1 e (x^2)+(z^2)≤1.

c3=ContourPlot3D[{(x^2)+(y^2)==1,(x^2)+(z^2)==1},{x,-1.5,1.5},{y,-1.5,1.5},{z,-1.5,1.5},Mesh->None,BoxRatios->Automatic,AxesLabel->{x,y,z},ContourStyle->{Opacity[0.6]}];

r3=RegionPlot3D[(x^2)+(y^2)≤1&&(x^2)+(z^2)≤1,{x,-1,1},{y,-1,1},{z,-1,1},Mesh->None,BoxRatios->Automatic,AxesLabel->{x,y,z},PlotStyle->{Opacity[0.6]},PlotPoints->60];

GraphicsGrid[{{c3,r3}},ImageSize->700]

Dobbiamo trovare una descrizione più opportuna per calcolare l’integrale. Dalle due disuguaglianze segue che (x^2)≤1, per cui -1≤ x≤1. Invece per y e z abbiamo -(Sqrt[1-(x^2)])≤ y≤(Sqrt[1-(x^2)])  e -(Sqrt[1-(x^2)])≤z≤ (Sqrt[1-(x^2)]).  Disegnamo E con questa nuova descrizione, per controllare che effettivamente sia lui

RegionPlot3D[-(Sqrt[1-(x^2)])≤y≤(Sqrt[1-(x^2)])&&-(Sqrt[1-(x^2)])≤z≤(Sqrt[1-(x^2)])&&-1≤x≤ 1,{x,-1,1},{y,-1,1},{z,-1,1},PlotStyle->{Opacity[0.7]},Mesh->None,PlotPoints->60,AxesLabel->{x,y,z},BoxRatios->Automatic]

E’ proprio lui. Calcoliamo l’integrale di (x^2)  su E , usando entrambe le descrizioni

Integrate[ (x^2)  Boole[-1≤x≤1&&-(Sqrt[1-(x^2)])≤y≤(Sqrt[1-(x^2)])&&-(Sqrt[1-(x^2)])≤z≤(Sqrt[1-(x^2)])],{x,-1,1},{y,-1,1},{z,-1,1}]

Integrate[(x^2) Boole[(x^2)+(y^2)≤1 &&(x^2)+(z^2)≤1],{x,-1,1},{y,-1,1},{z,-1,1}]

La seconda descrizione è decisamente semplice: le x-sezioni sono dei quadrati:

Manipulate[Grid[{{Show[RegionPlot3D[-(Sqrt[1-(x^2)])≤y≤(Sqrt[1-(x^2)])&&-(Sqrt[1-(x^2)])≤z≤(Sqrt[1-(x^2)])&&-1≤x≤ 1,{x,-1,1},{y,-1,1},{z,-1,1},PlotStyle->{Opacity[0.5]},Mesh->None,PlotPoints->20,AxesLabel->{x,y,z},BoxRatios->Automatic],ContourPlot3D[x==s,{x,-1,1},{y,-1,1},{z,-1,1},Mesh->None]], RegionPlot[-(Sqrt[1-(s^2)])≤y≤(Sqrt[1-(s^2)]) &&-(Sqrt[1-(s^2)])≤z≤(Sqrt[1-(s^2)]),{y,-1.2,1.2}, {z,-1.2,1.2}]}, {"Il piano a quota x","la z-sezione E(x)"}}], {s,-1,1}]

Esercizio 4

Dobbiamo dire se la funzione (1/(Sqrt[xy]))è in (L^1)((([0,1])^2)) e calcolarne in caso affermativo l’integrale. Prendiamo ad esempio (∫_0^1)(1/(Sqrt[xy]))dx . Esso è finito

Integrate[(1/(Sqrt[x y])),{x,0,1}]

Inoltre (∫_0^1)(2/(Sqrt[y]))dy è anch’esso finito. Quindi da Tonelli segue che (1/(Sqrt[xy])) è in (L^1)((([0,1])^2)). Per il Teorema di Fubini (∫_(([0,1])^2))(1/(Sqrt[x y]))dxdy=(∫_0^1)((∫_0^1)(1/(Sqrt[x y]))dx)dy, che quindi vale

Integrate[(2/(Sqrt[y])),{y,0,1}]

Mathematica può farlo insieme

Integrate[(1/(Sqrt[x y])),{x,0,1},{y,0,1}]