Esercizio 28

Valutare i seguenti integrali di superficie (∫_Σ)fdσ, dove
a) Σ è la parte di paraboloide x=(y^2)+(z^2) con x≤ 2, f(x,y,z)=z.

Una parametrizzazione si scrive in termini dell’angolo (attorno all’asse x) e dell’ascissa x. φ(x,θ)=(x,(Sqrt[x])cos(θ),(Sqrt[x])sin(θ)) con x∈[0,2],θ∈[0,2π]. Verifichiamo che la parametrizzazione è quella giusta.

Manipulate[Show[ParametricPlot3D[{x,(Sqrt[x]) Cos[t],(Sqrt[x]) Sin[t]},{t,0,T},{x,0,X},PlotRange->{{0,3},{-(Sqrt[2]),(Sqrt[2])},{-(Sqrt[2]),(Sqrt[2])}},Mesh->None,PlotStyle->{Blue},PerformanceGoal->"Quality"],ParametricPlot3D[{x,0,0},{x,0,X},PlotStyle->{Blue,Tube[0.02]},PlotRange->{{0,3},{-(Sqrt[2]),(Sqrt[2])},{-(Sqrt[2]),(Sqrt[2])}},Mesh->None,PerformanceGoal->"Quality"],ContourPlot3D[x== (y^2)+(z^2),{x,0,2},{y,-(Sqrt[2]),(Sqrt[2])},{z,-(Sqrt[2]),(Sqrt[2])},ContourStyle->{Red,Opacity[0.6]},Mesh->None]],{X,0.0001,2},{T,0.0001,2 Pi}]

Calcoliamo l’elemento di superficie e poi integriamo z=(Sqrt[x])Sin(θ) sulla superficie

FullSimplify[Norm[Minors[Grad[{x,(Sqrt[x]) Cos[t],(Sqrt[x]) Sin[t]},{x,t}],2]],Assumptions->x∈Reals&&t∈Reals&&x≥ 0]

Integrate[(Sqrt[x]) Sin[t] (1/2) (Sqrt[1+4 x]),{x,0,2},{t,0,2 Pi}]

b)Σ è la parte di sfera (x^2)+(y^2)+(z^2)=4 che giace sopra al cono z=(Sqrt[(x^2)+(y^2)]), f(x,y,z)=(x^2)z
La sfera si parametrizza mediante i due angoli θ∈[0,π] e ϕ∈[0,2π]. φ(ϕ,θ)=(2 sin(θ)cos(ϕ),2 sin(θ)sin(ϕ),2cos(θ)). Siccome consideriamo solo la calotta che è sopra al cono, questo nella parametrizzazione si riflette nel fatto che θ, l’angolo formato con l’asse z, deve essere compreso tra 0 e un certo (Subscript[θ, max]). Questo si trova calcolando la quota (Subscript[z, max])  alla quale la sfera interseca  il cono. Esso è (Sqrt[2]). Da qui segue che (Subscript[θ, max])=(π/4), per cui θ∈[0,(π/4)]. Controlliamo

Manipulate[Show[ParametricPlot3D[{2 Sin[t] Cos[f],2  Sin[t] Sin[f], 2 Cos[t]},{t,0,T},{f,0,F},PlotRange->{{-2,2},{-2,2},{-2,2}},Mesh->None,PlotStyle->Red,PerformanceGoal->"Quality"],ContourPlot3D[(x^2)+ (y^2)+(z^2)==4,{x,-2,2},{y,-2,2},{z,-2,2},ContourStyle->{Red,Opacity[0.5]},Mesh->None],ContourPlot3D[(Sqrt[(x^2)+ (y^2)])==z,{x,-2,2},{y,-2,2},{z,-2,2},ContourStyle->{Cyan,Opacity[0.5]},Mesh->None]],{F,0.0001,2 Pi},{T,0.0001,Pi/4}]

Calcoliamo l’elemento di superficie e integriamo (zx^2)=8 (sin^2)(θ)cos(θ)(cos^2)(ϕ).

FullSimplify[Norm[Minors[Grad[{2 Sin[t] Cos[f],2 Sin[t]  Sin[f],2  Cos[t]},{f,t}],2]],Assumptions->f∈Reals&&t∈Reals&&0≤t≤Pi/4]

Integrate[Integrate[32 Sin[t](((Sin[t] ))^2)Cos[t] (((Cos[f]))^2),{t,0,Pi/4}],{f,0,2 Pi}]

c)Σ è la parte di piano z+x-3=0 interna al cilindro (x^2)+(y^2)=1 e f(x,y,z)=xz.
Siccome le x e le y sono all’interno del disco centrato nell’origine e raggio 1, possiamo parametrizzarle come x=r cos(θ), y=r sin(θ). Da z=3-x segue che z=3-r cos(θ). Per cui una parametrizzazione è φ(r,θ)=(r cos(θ),r sin(θ),3-r cos(θ)), r∈[0,1], θ∈[0,2 Pi]. Verifichiamo

Manipulate[Show[ParametricPlot3D[{r  Cos[f],r   Sin[f], 3- r  Cos[f]},{r,0,R},{f,0,T},PlotRange->{{-2,2},{-2,2},{0,5}},Mesh->None,PlotStyle->Red,PerformanceGoal->"Quality"],ContourPlot3D[z+x-3==0,{x,-2,2},{y,-2,2},{z,0,5},ContourStyle->{Red,Opacity[0.2]},Mesh->None],ContourPlot3D[(x^2)+(y^2)==1,{x,-2,2},{y,-2,2},{z,0,5},ContourStyle->{Cyan,Opacity[0.2]},Mesh->None]],{R,0.0001,1},{T,0.0001,2 Pi}]

Calcoliamo l’elemento di superficie e integriamo xz=r cos(θ) (3-rcos(θ)).

FullSimplify[Norm[Minors[Grad[{r Cos[t] ,r Sin[t]  ,3-r  Cos[t]},{r,t}],2]],Assumptions->r∈Reals&&t∈Reals&&r≥0]

Integrate[Integrate[(Sqrt[2]) r(3 r Cos[t]-(r^2)(((Cos[t]))^2)),{r,0,1}],{t,0,2 Pi}]

d)Σ è la porzione regione triangolare di vertici (1,0,0), (0,2,0) e (0,0,2) e f(x,y,z)=x.
Σ è la parte di piano 2x+y+z=2 che si trova nel primo ottante (x,y,z >0). L’equazione del piano passante per i tre punti può essere ricavata subito. Possiamo parametrizzare Σ ad esempio con x ed y, che variano sulla proiezione di Σ sul piano xy (chiamiamo D questa proiezione), mentre z=2-2x-y. Quindi i nostri parametri sono x ed y, con (x,y)∈D. φ(x,y)=(x,y,2-2x-y) , con (x,y)∈D. Dobbiamo descrivere la regione D in (ℝ^2). Per z=0 sul piano xy si ha che la regione è quella compresa tra le rette x=0,y=0 e 2x+y=2. Ad esempio D={(x,y):0≤x≤1, 0≤y≤2-2x}. Verifichiamo se la parametrizzazione è corretta

Show[ParametricPlot3D[{x  ,y,2-2 x-y},{x,0,1},{y,0,2-2 x},PlotRange->{{0,2},{0,3},{0,3}},Mesh->None,PlotStyle->Red,PerformanceGoal->"Quality"],ContourPlot3D[{x==0,y==0,z==0,2 x+z+y-2==0},{x,0,2},{y,0,3},{z,0,3},ContourStyle->{{Red,Opacity[0.2]},{Red,Opacity[0.2]},{Red,Opacity[0.2]},{Red,Opacity[0.2]}},Mesh->None,PerformanceGoal->"Quality"],PlotRange->All]

Calcoliamo l’elemento di superficie e integriamo x=x.

FullSimplify[Norm[Minors[Grad[{x ,y  ,2-2x-y},{x,y}],2]],Assumptions->x∈Reals&&y∈Reals]

Integrate[Integrate[(Sqrt[6]) x,{y,0,2-2 x}],{x,0,1}]

Esercizio 29

Calcolare il baricentro di una lamina sottile di densità costante che ha la forma della parte di sfera (x^2)+(y^2)+(z^2)≤ 4 che giace sotto al piano z=1. Dobbiamo innanzitutto trovare una parametrizzazione per la superficie della lamina. Sarà quella della sfera ma dobbiamo prendere gli angoli opportuni.

Show[ParametricPlot3D[{2 Sin[t] Cos[f],2  Sin[t] Sin[f], 2 Cos[t]},{t,Pi/3,Pi},{f,0,2 Pi},PlotRange->{{-2,2},{-2,2},{-2,2}},Mesh->None,PlotStyle->Red,PerformanceGoal->"Quality"],ContourPlot3D[(x^2)+ (y^2)+(z^2)==4,{x,-2,2},{y,-2,2},{z,-2,2},ContourStyle->{Red,Opacity[0.2]},Mesh->None],ContourPlot3D[1==z,{x,-2,2},{y,-2,2},{z,-2,2},ContourStyle->{Cyan,Opacity[0.2]},Mesh->None]]

L’angolo θ (quello formato con l’asse z) andrà da un valore minimo (θ=0 polo nord, θ=π polo sud) (Subscript[θ, min])>0 a π. Il valore minimo è determinato dalla quota alla quale la sfera viene tagliata dal piano z=1. Si vede che l’angolo è (Subscript[θ, min])=(π/3). Quindi φ(θ,ϕ)=(2 sin(θ)cos(ϕ),2 sin(θ)sin(ϕ),2cos(θ)), θ∈[π/3,π], ϕ∈[0,2π]. Come prima l’elemento di superficie è 4 Sin(θ). L’area della lamina è (∫_(π/3)^π)((∫_0^(2π))4 sin(θ)dϕ)dθ=12π. Le coordinate del baricentro sono (Subscript[x, b])=(((∫_(π/3)^π)((∫_0^(2π))4 sin(θ)*2 sin(θ)cos(ϕ)dϕ)dθ)/(12π)), (Subscript[y, b])=(((∫_(π/3)^π)((∫_0^(2π))4 sin(θ)*2 sin(θ)sin(ϕ)dϕ)dθ)/(12π)),(Subscript[y, b])=(((∫_(π/3)^π)((∫_0^(2π))4 sin(θ)*2 cos(θ)dϕ)dθ)/(12π))

Integrate[4 Sin[t],{t,Pi/3,Pi},{f,0,2 Pi}]

Integrate[4 Sin[t]*2 Sin[t]*Cos[f],{t,Pi/3,Pi},{f,0,2 Pi}]/(12 Pi)

Integrate[4 Sin[t]*2 Sin[t]*Sin[f],{t,Pi/3,Pi},{f,0,2 Pi}]/(12 Pi)

Integrate[4 Sin[t]*2 Cos[t],{t,Pi/3,Pi},{f,0,2 Pi}]/(12 Pi)

Show[ParametricPlot3D[{2 Sin[t] Cos[f],2  Sin[t] Sin[f], 2 Cos[t]},{t,Pi/3,Pi},{f,0,2 Pi},PlotRange->{{-2,2},{-2,2},{-2,2}},Mesh->None,PlotStyle->{Red,Opacity[0.4]}],ListPointPlot3D[{{0,0,-1/2}},PlotStyle->{PointSize[0.03]}]]

Esercizio 30

Trovare il momento di inerzia rispetto all’asse z di una lamina sottile con la forma della superficie conica (z^2)=(x^2)+(y^2), 0≤ z≤2. Parametrizziamo la superficie con (r,θ). φ(r,θ)=(r cos(θ),r sin(θ),r), r∈[0,2], θ∈[0,2π].

Show[ContourPlot3D[(z^2)== (x^2)+(y^2),{x,-3,3},{y,-3,3},{z,-3,3},ContourStyle->{Blue,Opacity[0.2]},Mesh->None],ParametricPlot3D[{r Cos[t],r Sin[t],r},{r,0,2},{t,0,2 Pi},Mesh->None,PlotStyle->Red]]

Il momento di inerzia rispetto all’asse z è dato da (∫_Σ)(x^2)+(y^2)dσ. Calcoliamo l’elemento di superficie e integriamo (x^2)+(y^2)=(r^2) .

FullSimplify[Norm[Minors[Grad[{r Cos[t] ,r Sin[t]  ,r},{r,t}],2]],Assumptions->r∈Reals&&t∈Reals&&r≥0]

Integrate[(Sqrt[2]) r (r^2),{r,0,2},{t,0,2 Pi}]

Esercizio 12.7

Sia C={(x,y,z)∈(ℝ^3):z≤ 4,(x^2)+(y^2)≤ z, (x^2)+(y^2)≤1}. Disegnare C, dire se è compatto e calcolarne il volume e l’area superficiale. Trovare il flusso di F uscente da C, dove F=(Subscript[e, 1])x (cioè F=(x,0,0) ).
Disegnamo C. Esso è chiarament compatto (perchè chiuso e limitato)

SlideView[{ContourPlot3D[{z==4,(x^2)+(y^2)==z,(x^2)+(y^2)==1},{x,-2,2},{y,-2,2},{z,-1,5},Mesh->None,ContourStyle->{{Red,Opacity[0.2]},{Red,Opacity[0.2]},{Red,Opacity[0.2]}},ImageSize->600],RegionPlot3D[z≤4&&(x^2)+(y^2)≤1&&z≥ (x^2)+(y^2),{x,-2,2},{y,-2,2},{z,-1,5},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->600]}]

Il Volume è dato dal volume del cilindro di base il disco unitario ed altezza 3, e dal volume della regione interna al paraboloide di vertice l’origine, tagliato a quota z=1.

Show[RegionPlot3D[1.5 <=z≤4+1.5&&(x^2)+(y^2)≤1,{x,-2,2},{y,-2,2},{z,-1,6.5},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->500],RegionPlot3D[z≤1&&z≥ (x^2)+(y^2),{x,-2,2},{y,-2,2},{z,-1,5},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->500]]

Il volume del cilindro è 3π. Quello della porzione di paraboloide è (∫_((x^2)+(y^2)≤ z≤ 1))dxdydz=(∫_((x^2)+(y^2)≤ 1))((∫_((x^2)+(y^2))^1)dz)dxdy=(∫_((x^2)+(y^2)≤ 1))(1-(x^2)-(y^2))dxdy. Si integra sul disco unitario. Usando coordinate polari, l’integrale è (∫_0^1)((∫_0^(2π))r(1-(r^2))dθ)dr

Integrate[r-(r^3),{r,0,1},{t,0,2 Pi}]

Il volume del solido è 3π+(π/2). Per quanto riguarda l’area superficiale essa è data dall’area del disco unitario (che chiude il solido “in alto”, ovvero per z=4), la superficie del cilindro, e la superficie del paraboloide fino ad altezza z=1. Vediamo i grafici.

Show[ParametricPlot3D[{r Cos[t],r Sin[t],5},{r,0,1},{t,0,2 Pi},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->350],ParametricPlot3D[{Cos[t],Sin[t],z},{t,0,2 Pi},{z,1.5,4.5},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->350],ParametricPlot3D[{r Cos[t],r Sin[t],(r^2)},{t,0,2 Pi},{r,0,1},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->350],PlotRange->{{-1.5,1.5},{-1.5,1.5},{-0.5,5.5}}]

L’area del disco è π. L’area della superficie cilindrica è 6π. L’area della superficie del paraboloide si calcola a partire dalla parametrizzazione del paraboloide  φ(r,t)=(r cos(θ),r sin(θ),(r^2)), r∈[0,1], θ∈[0,2π].

FullSimplify[Norm[Minors[Grad[{r Cos[t] ,r Sin[t]  ,(r^2)},{r,t}],2]],Assumptions->r∈Reals&&t∈Reals&&r≥0]

Integrate[r (Sqrt[1+4 (r^2)]),{r,0,1},{t,0,2 Pi}]

L’area della superficie che racchiude il solido è (π/6)(5(Sqrt[5])-1)+π+6π. passiamo a calcolare il flusso del campo F uscente dalla superficie. Noi sappiamo calcolare il flusso di un campo F attraverso una superficie parametrica. Cosa significa uscente? L’integrale di un flusso attraverso una superficie parametrica, dove la superficie è data dalla parametrizzazione φ(u,v) , dove (u,v) vivono in un sottoinsieme D di (ℝ^2), è dato da (∫_D)F(φ(u,v))·(((∂φ)/(∂u))×((∂φ)/(∂v)))dudv. Il vettore ((∂φ)/(∂u))×((∂φ)/(∂v)) è il vettore ortogonale alla superficie parametrica. Chiaramente anche -((∂φ)/(∂u))×((∂φ)/(∂v)) è vettore ortogonale alla superficie. Quale di questi due considerare quando ci serve il flusso USCENTE? Chiaramente il vettore normale che “punta” verso l’esterno della superficie che racchiude il nostro solido. Quindi dobbiamo capire, una volta scritto il vettore normale alla superficie parametrica, che segno prendere! Iniziamo. Dobbiamo considerare il flusso uscente, quindi il flusso attraverso ogni porzione di superficie (il solido è racchiuso da una superficie che non ha un’unica parametrizzazione! E’ composto da diverse parti con parametrizzazioni diverse). Inziamo dal disco a quota z=4, cioè (x^2)+(y^2)≤1, z=4 ((Subscript[Σ, 1])). Si vede subito che il vettore ortogonale alla superficie nel punto (x,y,z)∈(Subscript[Σ, 1]) è α(0,0,1) per una certa costante α ( oppure anche α(0,0,-1), però questo punta verso il basso, quindi è entrante rispetto alla superficie chiusa che stiamo considerando). Mentre F su (Subscript[Σ, 1]) è (x,0,0) per ogni (x,y,z)∈(Subscript[Σ, 1]). Per cui F·ν=0 su tutta (Subscript[Σ, 1]). E così anche l’integrale di questa quantità. Altrimenti, rigorosamente, una parametrizzazione di (Subscript[Σ, 1]) è (r cos(θ),r sin(θ),4), r∈[0,1], θ∈[0,2π]. ((∂φ)/(∂r))×((∂φ)/(∂θ))

FullSimplify[Cross[D[{r Cos[t] ,r Sin[t]  ,4},r],D[{r Cos[t] ,r Sin[t]  ,4},t]]]

Per cui il vettore normale (quello di norma 1) ad un punto su (Subscript[Σ, 1])  è (0,0,1) (oppure anche (0,0,-1). E’ chiaro che quello uscente è (0,0,1) poichè punta verso l’alto. (ad ogni modo il prodotto scalare contro il flusso è nullo su tutta questa parte di superficie) (F è in blu, il vettore ortogonale alla superficie in rosso)

Manipulate[Show[ParametricPlot3D[{r Cos[t],r Sin[t],5},{r,0,1},{t,0,2 Pi},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->800],ParametricPlot3D[{Cos[t],Sin[t],z},{t,0,2 Pi},{z,1.5,4.5},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->550],ParametricPlot3D[{r Cos[t],r Sin[t],(r^2)},{t,0,2 Pi},{r,0,1},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->550],Graphics3D[{Red,Arrow[{{R Cos[T],R Sin[T],5},{ R Cos[T],R Sin[T],6}}]}],Graphics3D[{Blue,Arrow[{{R Cos[T],R Sin[T],5},{ R Cos[T]+R Cos[T],R Sin[T],5}}]}],PlotRange->{{-2,2},{-2,2},{4.6,6.5}}],{R,0,1},{T,0,2 Pi}]

{0,0,r}.{r Cos[t],0,0}

Passiamo al flusso attaraverso la superficie cilindrica (Subscript[Σ, 2]). Una parametrizzazione è φ(θ,ζ)=(Cos(θ),Sin(θ),ζ), θ∈[0,2π], ζ∈[1,3]. Il vettore ortogonale alla superficie è ((∂φ)/(∂θ))×((∂φ)/(∂ζ)) è (Cos(θ),Sin(θ),0). E’ entrante o uscente? (è quello in rosso. F, il flusso, è in blu)

FullSimplify[Cross[D[{ Cos[t] , Sin[t]  ,z},t],D[{ Cos[t] , Sin[t]  ,z},z]]]

Manipulate[Show[ParametricPlot3D[{ Cos[t], Sin[t],z},{z,1,4},{t,0,2 Pi},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->600],Graphics3D[{Red,Arrow[{{ Cos[T], Sin[T],Z},{ 2  Cos[T],2  Sin[T],Z}}]}],Graphics3D[{Blue,Arrow[{{ Cos[T], Sin[T],Z},{  Cos[T]+ Cos[T], Sin[T],Z}}]}],PlotRange->{{-2,2},{-2,2},{0.5,4.5}}],{Z,1,4},{T,0,2 Pi}]

E’ quello uscente. Per cui calcoliamo il flusso attraverso questa superficie: (∫_0^(2π))((∫_1^3)F·(((∂φ)/(∂θ))×((∂φ)/(∂ζ)))dζ)dθ

Integrate[{Cos[t],0,0}.{Cos[t],Sin[t],0},{t,0,2 Pi},{z,1,4}]

Calcoliamo infine il flusso uscente da (Subscript[Σ, 3]), la superficie sulla porzioen di paraboloide. Una parametrizzazione è φ(r,θ)=(r cos(θ),r sin(θ),(r^2)). ((∂φ)/(∂r))×((∂φ)/(∂θ)). E’ entrante o uscente?

FullSimplify[Cross[D[{r  Cos[t] , r Sin[t]  ,(r^2)},r],D[{ r Cos[t] ,r  Sin[t]  ,(r^2)},t]]]

Manipulate[Show[ParametricPlot3D[{ r Cos[t],r Sin[t],(r^2)},{r,0,1},{t,0,2 Pi},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->600],Graphics3D[{Red,Arrow[{{ R Cos[T], R Sin[T],(R^2)},{ R  Cos[T]-2 (R^2) Cos[T],R  Sin[T]-2 (R^2) Sin[T],(R^2)+R}}]}],Graphics3D[{Blue,Arrow[{{ R Cos[T], R Sin[T],(R^2)},{ 2  R Cos[T],R Sin[T],(R^2)}}]}],PlotRange->{{-2,2},{-2,2},{-0.5,1.5}}],{R,0,1},{T,0,2 Pi}]

E’ entrante. Quindi il vettore ortogonale uscente sarà (2(r^2) cos(θ),2(r^2)sin(θ),-r). (cambiamo segno nella precedente espressione e verifichiamo). Per cui il flusso è

Integrate[{r Cos[t],0,0}.{2 (r^2) Cos[t],2 (r^2) Sin[t],-r},{r,0,1},{t,0,2 Pi}]

Infine il flusso uscente attraverso tutta la superficie sarà dato dalla somma delle singole componenti, ovvero (π/2)+3π.

Esercizio 10.8

Sia E={(x,y,z)∈(ℝ^3):(x^2)+(y^2)+(z^2)≤ 9, z<(Sqrt[(x^2)+(y^2)])}. Descrivere E, disegnarlo, calcolarne area superficiale e volume e infine calcolare il flusso uscente da E del campo ∇u, dove u(x,y,z)=(x^2)+(y^2)+(z^2);

E (l’insieme pieno) può essere descritto in coordinate sferiche (vedere l’es. 28 per i dettagli). (x,y,z)=(r sin(θ)cos(ϕ),r sin(θ) sin(ϕ),r cos(θ)), r∈[0,3], θ∈[π/4,π], ϕ∈[0,2π]. Il valore (Subscript[θ, min])=π/4 si ricava in maniera del tutto analoga all’esercizio 28.

Show[ParametricPlot3D[{3 Sin[t] Cos[f],3  Sin[t] Sin[f],3  Cos[t]},{t,Pi/4,Pi},{f,0,2 Pi},PlotRange->{{-3,3},{-3,3},{-3,3}},Mesh->None,PlotStyle->Red],ContourPlot3D[(x^2)+ (y^2)+(z^2)==9,{x,-3,3},{y,-3,3},{z,-3,3},ContourStyle->{Red,Opacity[0.2]},Mesh->None],ContourPlot3D[(Sqrt[(x^2)+(y^2)])==z,{x,-3,3},{y,-3,3},{z,0,2},ContourStyle->{Cyan,Opacity[0.2]},Mesh->None]]

Iniziamo con il calcolo del volume. Ricordiamo che il determinante dello Jacobiano della trasformazione è (r^2)Sin(θ). Per cui

Integrate[(r^2) Sin[t],{r,0,3},{t,Pi/4,Pi},{f,0,2 Pi}]

Passiamo all’area superficiale. La superficie è composta da due parti: una parte è sul cono l’altra è sulla sfera. La parte sulla sfera ((Subscript[Σ, 1])) è parametrizzata da φ(θ,ϕ)=(3 sin(θ) cos(ϕ), 3 sin(θ) cos(ϕ), 3 cos(θ) ), ϕ∈[0,2π], θ∈[π/4,π]. L’elemento di area è 9 sin(θ). Per cui l’area della parte sulla sfera è

Integrate[9 Sin[t],{t,Pi/4,Pi},{f,0,2 Pi}]

La parte sulla superficie del cono ((Subscript[Σ, 2])) è parametrizzata da φ(r,θ)=(r cos(ϕ), r sin(ϕ), r), r∈[0,(3/(Sqrt[2]))] , ϕ∈[0,2π].

FullSimplify[Norm[Minors[Grad[{r Cos[f],r Sin[f],r},{r,f}],2]],Assumptions->r≥0&&f∈Reals]

Integrate[(Sqrt[2]) r,{r,0,3/(Sqrt[2])},{f,0,2 Pi}]

L’area della parte sul cono è ((9π)/(Sqrt[2])). Passiamo al calcolo del flusso. Dobbiamo calcolarlo su ogni porzione. Partiamo da (Subscript[Σ, 1]). Essa è parametrizzata da (θ,ϕ). Calcoliamo il vettore ortogonale alla superficie ((∂φ)/(∂θ))×((∂φ)/(∂ϕ)). Questo vettore è quello uscente?

FullSimplify[Cross[D[{3  Sin[t] Cos[f] , 3 Sin[t] Sin[f]  ,3 Cos[t]},t],D[{ 3  Sin[t] Cos[f] , 3 Sin[t] Sin[f]  ,3 Cos[t]},f]]]

Manipulate[Show[ParametricPlot3D[{3  Sin[t] Cos[f] , 3 Sin[t] Sin[f]  ,3 Cos[t]},{t,Pi/4,Pi},{f,0,2 Pi},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->600],Graphics3D[{Red,Arrow[{{ 3  Sin[T] Cos[F] , 3 Sin[T] Sin[F]  ,3 Cos[T]},{ 3  Sin[T] Cos[F]+9 Cos[F] ((Sin[T])^2) , 3 Sin[T] Sin[F] + 9 Sin[F] ((Sin[T])^2),3 Cos[T]+9 Cos[T] Sin[T]}}]}],Graphics3D[{Blue,Arrow[{{ 3  Sin[T] Cos[F] , 3 Sin[T] Sin[F]  ,3 Cos[T]},{ 3  Sin[T] Cos[F]+2  (3  Sin[T] Cos[F]), 3 Sin[T] Sin[F]  +2 ( 3 Sin[T] Sin[F] ),3 Cos[T]+2 (3 Cos[T])}}]}],PlotRange->{{-9,9},{-9,9},{-9,9}}],{F,0,2 Pi},{T,Pi/4, Pi}]

Il vettore ortogonale trovato è quello uscente. F=∇u=(2x, 2y, 2z)=2 (3 sin(θ) cos(ϕ), 3 sin(θ) sin(ϕ), 3 cos(θ)). Per cui l’integrale del flusso su questa superficie è

Integrate[{6 Sin[t] Cos[f],6 Sin[t] Sin[f],6 Cos[t]}.{9 Cos[f] ((Sin[t])^2),9 Sin[f] ((Sin[t])^2),9 Cos[t] Sin[t]},{t,Pi/4,Pi},{f,0,2 Pi}]

Troviamo il flusso sulla parte di superficie che è sul cono ((Subscript[Σ, 2])). Essa è parametrizzata da (r,ϕ). Troviamo  ((∂φ)/(∂θ))×((∂φ)/(∂ϕ)). Questo vettore è quello uscente?

FullSimplify[Cross[D[{r Cos[t] , r Sin[t] ,r},r],D[{ r Cos[t] , r  Sin[t]  ,r},t]]]

Manipulate[Show[ParametricPlot3D[{r  Cos[t] , r  Sin[t]  ,r},{r,0,1},{t,0,2 Pi},PlotStyle->{Red,Opacity[0.4]},Mesh->None,PlotPoints->60,ImageSize->600],Graphics3D[{Red,Arrow[{{ R Cos[T], R Sin[T], R},{ R Cos[T]-R Cos[T], R Sin[T]-R Sin[T], R+R}}]}],Graphics3D[{Blue,Arrow[{{ R Cos[T], R Sin[T], R},{  3 R Cos[T],3  R Sin[T],3 R}}]}],PlotRange->{{-2,2},{-2,2},{0,2}}],{R,0,1},{T,0,2 Pi}]

E’ il vettore entrante che abbiamo calcolato. Il vettore ortogonale uscente è (r cos(ϕ), r sin(ϕ), -r). F=2(r cos(ϕ),r sin(ϕ),r). Il flusso uscente è

Integrate[{2 r Cos[t],2 r Sin[t],2  r}.{r Cos[t], r Sin[t],-r},{r,0,1},{t,0,2 Pi}]

Quindi il flusso uscente è dato semplicemente dal flusso uscente dalla superficie sulla sfera: 54π(2+(Sqrt[2])).

Esercizio 10.22

Calcolare il flusso del campo F=((x^4),y,z) attraverso la superficie parametrica φ(u,v)=(u,v,1-(u^2)-(v^2)) dove (u,v)∈D={(u,v):(u^2)+(v^2)≤ 1}.

ParametricPlot3D[{u,v,1-(u^2)-(v^2)},{u,-1,1},{v,-(Sqrt[1-(u^2)]),(Sqrt[1-(u^2)])}, Mesh->None,PlotStyle->Opacity[0.6]]

F(φ(u,v))=((u^4),v,1-(x^2)-(y^2)). Calcoliamo ((∂φ)/(∂u))×((∂φ)/(∂v))

FullSimplify[Cross[D[{u,v,1-(u^2)-(v^2)},u],D[{ u,v,1-(u^2)-(v^2)},v]]]

Integrate[({(u^4),v,1-(u^2)-(v^2)}.{2 u,2 v,1})*Boole[(u^2)+(v^2)≤1],{u,-1,1},{v,-1,1}]

Calcolo del volume e della superficie della palla unitaria in (ℝ^n)

Calcoliamo la formula che esprime il volume e l’area della superficie della palla unitaria in (ℝ^n). la chiameremo (Subscript[B, n]):={((Subscript[x, 1]),(Subscript[x, 2]),... , (Subscript[x, n]))∈(ℝ^n): ((Subscript[x, 1])^2)+... + ((Subscript[x, n])^2)≤ 1} e ∂(Subscript[B, n]):={((Subscript[x, 1]),(Subscript[x, 2]),... , (Subscript[x, n]))∈(ℝ^n): ((Subscript[x, 1])^2)+... + ((Subscript[x, n])^2)= 1} la sua frontiera. Ricordiamo la formula di integrazione su una palla di una funzione radiale g(|x|), dove |x|=(Sqrt[((Subscript[x, 1])^2)+... + ((Subscript[x, n])^2)]): (∫_(B(0,R)))g(|x|)d(Subscript[x, 1])...d(Subscript[x, n])=(∫_0^R)((∫_(∂B(0,r)))g(r)dσ)dr=(∫_0^R)g(r)((∫_(∂B(0,r)))dσ)dr=(∫_0^R)g(r)Area(∂B(0,r))dr. Diamo per buono ora (si può vedere con cambiamenti di variabile, ad. esempio come fatto sui fogli di esercizi) che Area(∂B(0,r))=(r^(n-1))Area(∂B(0,1)), per cui (∫_(B(0,R)))g(|x|)d(Subscript[x, 1])...d(Subscript[x, n])=Area(∂B(0,1))(∫_0^R)(r^(n-1))g(r)dr. Date queste premesse, calcoliamo l’integrale (∫_(ℝ^n))(e^(-(((Subscript[x, 1])^2)+... + ((Subscript[x, n])^2))))d(Subscript[x, 1])...d(Subscript[x, n]) in due modi diversi. Direttamente. Otteniamo (∫_(ℝ^n))(e^(-(((Subscript[x, 1])^2)+... + ((Subscript[x, n])^2))))d(Subscript[x, 1])...d(Subscript[x, n])=((∫_(ℝ^n))(e^(-((Subscript[x, 1])^2)))d(Subscript[x, 1]))·...·((∫_(ℝ^n))(e^(-((Subscript[x, n])^2)))d(Subscript[x, n]))=((((Sqrt[π])))^n). Ora lo calcoliamo come un integrale su sfere, considerando (ℝ^n) come una sfera di raggio r->+∞. La funzione integranda è chiaramente radiale (è (e^(-(r^2)))). (∫_(ℝ^n))(e^(-(((Subscript[x, 1])^2)+... + ((Subscript[x, n])^2))))d(Subscript[x, 1])...d(Subscript[x, n])=Area(∂B(0,1))(∫_0^(+∞))(r^(n-1))(e^(-(r^2)))dr. Quest’ultimo integrale, col cambiamento di variabile (r^2)=t diventa (1/2)Area(∂B(0,1))(∫_0^(+∞))(r^((n/2)-1))(e^(-t))dt e l’ultimo integrale è la definizione di Γ((n/2)).  Per cui abbiamo ottenuto (1/2)Area(∂B(0,1))Γ((n/2))=((((Sqrt[π])))^n), cioè Area(∂B(0,1))=((2(π^(n/2)))/(Γ((n/2)))). Per calcolare il volume della palla unitaria, sempre con la formula di integrazione per sfere, scriviamo Vol(B(0,1))=(∫_(B(0,1)))d(Subscript[x, 1])...d(Subscript[x, n])=Area(∂B(0,1))(∫_0^1)(r^(n-1))dr=((Area(∂B(0,1)))/n). Quindi in definitiva Vol((Subscript[B, n]))=((2(π^(n/2)))/(nΓ((n/2)))), Area((Subscript[B, n]))=n Vol((Subscript[B, n])).  Disegnamo la situazione. Il valore della funzione g in un punto (x,y,z) della palla è rappresentato mediante gradazione di colore. Se g è radiale, il valore dipenderà solo dalla distanza dall’origine. Quindi su ogni sfera ∂B(0,r) la funzione g sarà costante. Per cui il suo integrale sulla specifica sfera sarà uguale al valore g(r) per l’area della superficie di ∂B(0,r).

Manipulate[Show[ContourPlot3D[{(x^2)+(y^2)+(z^2)==1},{x,-1,1},{y,-1,1},{z,-1,1},Mesh->None,ContourStyle->{Blue,Opacity[0.2]},PerformanceGoal->"Quality",ImageSize->600],ContourPlot3D[(x^2)+(y^2)+(z^2)==r,{x,-1,1},{y,-1,1},{z,-1,1},ColorFunction->Function[{x,y,z},Hue[ ((x^2)+(y^2)+(z^2))]],ColorFunctionScaling->False,Mesh->None,ContourStyle->{Opacity[0.7]},PerformanceGoal->"Quality",ImageSize->600]],{r,0,1}]

Esercizio 7.59

Data la sfera (x^2)+(y^2)+(z^2)=(a^2), a>0, presi -a≤(Subscript[h, 2])<(Subscript[h, 1])≤ a, calcolare l’area superficiale del segmento sferico, ovvero la porzione di sfera tra i piani z=(Subscript[h, 2]) e z=(Subscript[h, 1]). Preso il cilindro tangente alla sfera nel piano equatoriale (x^2)+(y^2)=(a^2), vediamo che l’area laterale del cilindro compreso tra i due piani ad altezza (Subscript[h, 2]) e (Subscript[h, 1])è la stessa del segmento sferico calcolata prima.
L’area della superficie laterale del cilindro è chiaramente 2πa((Subscript[h, 1])-(Subscript[h, 2])). Calcoliamo l’area della superficie del segmento sferico come area di una superficie di rotazione (a=1,(Subscript[h, 1])=1/2,(Subscript[h, 2])=-2/3).

ParametricPlot[{z,(Sqrt[1-(z^2)])},{z,-2/3,1/2},PlotStyle->{Orange,Thick},PlotRange->{{-1,1},{0,1}}]

Manipulate[ParametricPlot3D[{z,(Sqrt[1-(z^2)]) Sin[t],(Sqrt[1-(z^2)]) Cos[t]},{z,-2/3,1/2},{t,0,T},Mesh->None,PlotStyle->{Opacity[0.6]},PlotRange->{{-1,1},{-1,1},{-1,1}},PerformanceGoal->"Quality"],{T,0.0001,2 Pi}]

L’area del segmento sferico è 2π(∫_γ)xds, dove γ(z)=(z,(Sqrt[1-(z^2)])). Per cui

Integrate[(Sqrt[1-(z^2)])* (Sqrt[(1/(1-(z^2)))]),{z,h2,h1},Assumptions->z>0&&h2<h1&&-1≤ h2<h1≤1]