Esercizio 1

G è il solido ottenuto ruotando attorno all’asse z il disco sul piano xz di centro (10,0,0) e raggio uno e intersecandolo col semipiano z≥0. Sia S la frontiera di G, composta da (Subscript[S, 1]), la parte superiore di S, ed (Subscript[S, 2]), la parte inferiore di S. Sia poi F(x,y,z)=((x^2)-(y/((x^2)+(y^2))),x+(x/((x^2)+(y^2))),z+(y^2)). Determinare (Subscript[I, 1])-(Subscript[I, 2]) la differenza tra il flusso uscente da S attraverso (Subscript[S, 1]) e il flusso uscente da S attraverso (Subscript[S, 2]).

Grid[{{Show[ContourPlot3D[(((10-(Sqrt[(x^2)+(y^2)])))^2)+(z^2)==4,{x,-12,12},{y,-12,12},{z,0,2},Mesh->None,ContourStyle->{Opacity[0.7]}],ParametricPlot3D[{r Cos[t],r Sin[t],0},{r,8,12},{t,0,2 Pi},Mesh->None,PlotStyle->{Opacity[0.7]}],PlotRange->{{-12,12},{-12,12},{0,2}},ImageSize->400,BoxRatios->{12,12,1}],Show[ParametricPlot3D[{r Cos[t],r Sin[t],0},{r,8,12},{t,0,2 Pi},Mesh->None,PlotStyle->{Opacity[0.7]}],Graphics3D[Arrow[{{10,0,0},{10,0,-3}}]],Graphics3D[Arrow[{{-10,0,0},{-10,0,-3}}]],Graphics3D[Arrow[{{0,10,0},{0,10,-3}}]],Graphics3D[Arrow[{{0,-10,0},{0,-10,-3}}]],ImageSize->400,PlotRange->{2,-3}]}}]

{(x^2)-(y/((x^2)+(y^2))), x+(x/((x^2)+(y^2))),z+(y^2)}/.z->0

I2=FullSimplify[Integrate[({(x^2)-(y/((x^2)+(y^2))),x+(x/((x^2)+(y^2))),(y^2)}.{0,0,-1})*Boole[64≤(x^2)+(y^2)≤ 144],{x,-12,12},{y,-12,12}]]

Div[{(x^2)-(y/((x^2)+(y^2))), x+(x/((x^2)+(y^2))),z+(y^2)},{x,y,z}]

Integrate[(1+2 x)*Boole[z≤ (Sqrt[4-(((10-(Sqrt[(x^2)+(y^2)])))^2)])],{x,-12,12},{y,-12,12},{z,0,2}];

I0=Integrate[(1+2 Cos[t]) r * (Sqrt[4-(((10-r))^2)]),{r,8,12},{t,0,2 Pi}]

I1=I0-I2;

I1-I2

Esercizio 2

Sia γ(t)=(Sin(t), Cos(t),Sin(2t)). con t∈[0,2π] e F(x,y,z)=(y+Sin(x),(z^2)+Cos(y),(x^3)). Calcolare (∫_γ)F·dγ. Osserviamo che γ è già data con una parametrizzazione, quindi ci viene richiesta la circuitazione nel senso di γ come richiesto dall’esercizio. In più si vede che γ(t)=(Sin(t), Cos(t),2 Sin(t) Cos(t)) è l’immagine tramite la funzione p(x,y)=(x,y,2xy) della circonferenza unitaria in (R^2) parametrizzata da (Sin(t),Cos(t)). γ è il bordo di una superficie cartesiana, cioè p(x,y)=(x,y,2xy) con (x,y)∈D, con D disco unitario in (R^2).  Bisogna capire qual è l’orientamento della circonferenza unitaria ∂D in (R^2) dal quale proviene l’orientamento di γ in (R^3) (in altre parole γ proviene da un orientamento positivo o negativo di ∂D rispetto a D? Che è come chiedersi γ è (SuperPlus[∂])S o (SuperMinus[∂])S?) e applicare opportunamente Stokes per calcolare la circuitazione richiesta, che non può essere calcolata direttamente come integrale di linea (complicato, infattibile)

Grid[{{Show[ParametricPlot3D[{r Cos[t],r Sin[t],(r^2) Sin[2 t]},{r,0,1},{t,0,2 Pi},Mesh->None,PlotStyle->Opacity[0.7]],ParametricPlot3D[{Cos[t], Sin[t], Sin[2 t]},{t,0,2 Pi},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ImageSize->350,PlotRange->{{-1,1},{-1,1},{-1,1}}],Show[Plot3D[2 x y,{x,-1,1},{y,-1,1},Mesh->None,PlotStyle->Opacity[0.7]],ParametricPlot3D[{r Cos[t], r Sin[t], 0},{t,0,2 Pi},{r,0,1},Mesh->None,PlotStyle->{Opacity[0.9]}],ParametricPlot3D[{Cos[t], Sin[t], Sin[2 t]},{t,0,2 Pi},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{Cos[t], Sin[t], 0},{t,0,2 Pi},Mesh->None,PlotStyle->{Orange,Tube[0.02]}],ImageSize->350,PlotRange->{{-1,1},{-1,1},{-1,1}},BoxRatios->{1,1,1}],Manipulate[Show[ParametricPlot3D[{Sin[t], Cos[t], Sin[2 t]},{t,0,T},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{Sin[t], Cos[t], 0},{t,0,T},Mesh->None,PlotStyle->{Orange,Tube[0.02]}],PlotRange->{{-1,1},{-1,1},{-1,1}}],{T,0.0001,2 Pi}]},{Manipulate[Show[RegionPlot[(x^2)+(y^2)≤1,{x,-1,1},{y,-1,1},PlotStyle->{Opacity[0.1]},PerformanceGoal->"Quality"],ParametricPlot[{Sin[t],Cos[t]},{t,0,T},PlotStyle->{Orange,Thick}]],{T,0.0001,2Pi}]}}]

Vediamo dai grafici che effettivamente nelle nostre notazioni (vedi fogli di esercizi) γ=(SuperMinus[∂])S, cioè è il bordo di S orientato negativamente (proviene dal bordo di D orientato negativamente tramite la parametrizzazione di S). Quindi (T. Stokes) (∫_γ)F·dγ=(∫_((SuperMinus[∂])S))F·d(SuperMinus[∂])S=-(∫_((SuperPlus[∂])S))F·d(SuperPlus[∂])S=-(∫_S)rotF·(Subscript[ν, p])d(Subscript[σ, p]), dove (Subscript[ν, p])(Subscript[dσ, p])=(((∂p)/(∂x))×((∂p)/(∂y)))dxdy.

Integrate[((Curl[{y+Sin[x],(z^2)+Cos[y],(x^3)},{x,y,z}]/.z->2 x y).Cross[{1,0,2 y},{0,1,2 x}])*Boole[(x^2)+(y^2)≤1],{x,-1,1},{y,-1,1}]

Allora (∫_γ)F·dγ=-(∫_S)rotF·(Subscript[ν, p])d(Subscript[σ, p])=π.

Esercizio 3

Calcolare il flusso del rotore di F(x,y,z)=((y^3)z,(x^3)(e^z),-(xyz^2)) uscente dalla porzione di sfera (x^2)+(y^2)+(z^2)=16 contenuta nel semipianoy≥-1. Qui osserviamo qual è la corretta orientazione del bordo di S (sia S questa superficie) ∂S corrispondente alla scelta della normale esterna (ad. es “analogia” col caso cartesiano, o regola della mano destra) (!!! Dopo aver visto i grafici, ruotare la prima immagine per avere l’asse y verticale: allora notare quale è la parametrizzazione giusta per il bordo di S, e guardare il grafico in (R^2) accanto dove c’è il piano xz)

Grid[{{Manipulate[Show[ParametricPlot3D[{4 Sin[t] Sin[f],4 Cos[t],4 Sin[t] Cos[f]},{f,0,2 Pi},{t,0,ArcTan[-1,(Sqrt[15])]},PerformanceGoal->"Quality",Mesh->None,PlotStyle->{Opacity[0.7]}],ParametricPlot3D[{(Sqrt[15]) Sin[t],-1,(Sqrt[15]) Cos[t]},{t,0,T},PlotStyle->{Red,Tube[0.03]}],PlotRange->{{-4,4},{-4,4},{-4,4}},AxesLabel->{X,Y,Z}],{T,0.0001,2 Pi}],Manipulate[Show[RegionPlot[(x^2)+(z^2)≤15,{z,-(Sqrt[15]),(Sqrt[15])},{x,-(Sqrt[15]),(Sqrt[15])},PerformanceGoal->"Quality",PlotStyle->{Opacity[0.1]},AxesLabel->{Z,X}],ParametricPlot[{(Sqrt[15]) Cos[t],(Sqrt[15]) Sin[t]},{t,0, T} ,PlotStyle->{Orange,Thick}],PlotRange->{{-(Sqrt[15]),(Sqrt[15])},{-(Sqrt[15]),(Sqrt[15])}},AxesLabel->{Z,X}],{T,0.0001,2 Pi}]}}]

Si vede che una parametrizzazione di ∂S che è compatibile con la normale esterna (Subscript[ν, e]) è la seguente ((Sqrt[15]) Sin(t),-1,(Sqrt[15])Cos(t)) con t∈[0,2π] (chiamiamola (SuperPlus[∂])S). Quindi (∫_S)rot F·(Subscript[ν, e])d(Subscript[σ, s])=(∫_((SuperPlus[∂])S))F·d(SuperPlus[∂])S. Calcoliamo quest’ultimo integrale

Integrate[({(y^3) z,(x^3) Exp[z],-x y (z^2)}/.{x->(Sqrt[15]) Sin[t],y->-1,z->(Sqrt[15]) Cos[t]}).{(Sqrt[15]) Cos[t],0,-(Sqrt[15]) Sin[t]},{t,0,2 Pi}]

Proviamo a calcolare direttamente il flusso del rotore con Mathematica (a mano non è fattibile) per vedere se effettivamente la scelta fatta per l’orientazione del bordo e la normale esterna sono compatibili. Parametrizziamo la sfera come segue (osserviamo che è la parametrizzazione “canonica” fatta però trattando l’asse y come l’asse z, e gli altri due assi di conseguenza) φ(θ,ϕ)=(4 Sin(θ)Sin(ϕ), 4 Cos(θ),4 Sin(θ)Cos(ϕ)) con θ∈[0,π-ArcTan(15)]. Di conseguenza (Subscript[ν, e])dσ=(((∂φ)/(∂θ))×((∂φ)/(∂ϕ)))dθdϕ è dato da  (16 (Sin^2)(θ)Sin(ϕ),16 Cos(θ)Sin(θ),16 (Sin^2)(θ)Cos(ϕ))dθdϕ.

Integrate[(Curl[{(y^3) z,(x^3) Exp[z],-x y (z^2)},{x,y,z}]/.{x->4 Sin[t] Sin[f],y->4 Cos[t],z->4 Sin[t] Cos[f]}).{16 ((Sin[t])^2) Sin[f],16 Cos[t] Sin[t],16 ((Sin[t])^2) Cos[f]},{t,0,π-ArcTan[(Sqrt[15])]},{f,0,2 Pi}]

Esercizio 4

Utilizzare il Teorema di Stokes per
a) Calcolare (∫_C)F·dC, dove F=((x^2)y,((x^3)/3),xy)e C è la curva intersezione tra la superficie z=(y^2)-(x^2) con il cilindro (x^2)+(y^2)=1, orientata in senso orario se vista dall’alto.
b)Verificare il T. di Stokes se F=((y^2),x,(z^2))  e S è la parte di paraboloide z=(x^2)+(y^2) che giace sotto z=1 orientata “verso l’alto”.
Iniziamo da a). Osserviamo che la curva, vivendo sul cilindro, e su una superficie cartesiana (x,y,(y^2)-(x^2)), è l’immagine della circonferenza unitaria in (R^2) tramite la parametrizzazione p(x,y,(y^2)-(x^2)). Inoltre C è per l’appunto il bordo in (R^3)  di una superficie (cartesiana) S che è l’immagine tramite la parametrizzazione p del disco unitario D in (R^2). Ricapitolando, C=p(∂D) bordo della superficie S=p(D), con D il disco unitario in (R^2). Cerchiamo di trovare una parametrizzazione di C che fornisca l’orientamento richiesto dal problema e capire se C è (nelle nostre notazioni) (SuperPlus[∂])S o (SuperMinus[∂])S e poi applicare Stokes. Vediamo le seguenti immagini

Grid[{{Show[ParametricPlot3D[{r Cos[t],r Sin[t],-(r^2) Cos[2 t] },{r,0,1},{t,0,2 Pi},Mesh->None,PlotStyle->Opacity[0.7]],ParametricPlot3D[{Cos[t], Sin[t], - Cos[2 t]},{t,0,2 Pi},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ImageSize->350,PlotRange->{{-1,1},{-1,1},{-1,1}}],Show[Plot3D[(y^2)-(x^2),{x,-1,1},{y,-1,1},Mesh->None,PlotStyle->Opacity[0.7]],ParametricPlot3D[{r Cos[t], r Sin[t], 0},{t,0,2 Pi},{r,0,1},Mesh->None,PlotStyle->{Opacity[0.9]}],ParametricPlot3D[{Cos[t], Sin[t],- Cos[2 t]},{t,0,2 Pi},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{Cos[t], Sin[t], 0},{t,0,2 Pi},Mesh->None,PlotStyle->{Orange,Tube[0.02]}],ImageSize->350,PlotRange->{{-1,1},{-1,1},{-1,1}},BoxRatios->{1,1,1}],Manipulate[Show[ParametricPlot3D[{Sin[t], Cos[t], -Cos[2 t]},{t,0,T},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{Sin[t], Cos[t], 0},{t,0,T},Mesh->None,PlotStyle->{Orange,Tube[0.02]}],PlotRange->{{-1,1},{-1,1},{-1,1}}],{T,0.0001,2 Pi}]},{Manipulate[Show[RegionPlot[(x^2)+(y^2)≤1,{x,-1,1},{y,-1,1},PlotStyle->{Opacity[0.1]},PerformanceGoal->"Quality"],ParametricPlot[{Sin[t],Cos[t]},{t,0,T},PlotStyle->{Orange,Thick}]],{T,0.0001,2Pi}]}}]

Siamo in una situazione simile a quella dell’esercizio 2. L’orientamento orario della curva vista dall’alto è dato da un orientamento orario sul piano (xy) della circonferenza unitaria tramite la parametrizzazione p(x,y)=(x,y,(y^2)-(x^2)). Quindi C=(SuperMinus[∂])S. Per  (Stokes)  (∫_C)F·dC=(∫_((SuperMinus[∂])S))F·d(SuperMinus[∂])S=-(∫_((SuperPlus[∂])S))F·d(SuperPlus[∂])S=-(∫_S)rotF·(Subscript[ν, p])d(Subscript[σ, p]), dove (Subscript[ν, p])(Subscript[dσ, p])=(((∂p)/(∂x))×((∂p)/(∂y)))dxdy.

Integrate[((Curl[{(x^2) y,((x^3)/3),x y},{x,y,z}]/.z->(y^2)-(x^2)).Cross[{1,0,-2 x},{0,1,2 y}])*Boole[(x^2)+(y^2)≤1],{x,-1,1},{y,-1,1}]

Quindi  (∫_γ)F·dγ=-(∫_S)rotF·(Subscript[ν, p])d(Subscript[σ, p])=-π. Passiamo a b). S è superficie cartesiana, immagine tramite la parametrizzazione p(x,y)=(x,y,(x^2)+(y^2)) del disco unitario D in (R^2) (lo si può vedere subito: z≤1 e z=(x^2)+(y^2) danno (x^2)+(y^2)≤1 che è il dominio della parametrizzazione; si vede subito anche graficamente). S orientata verso l’alto significa che consideriamo la normale “canonica” di una superficie cartesiana (Subscript[ν, p]). Per cui dobbiamo orientare bene il bordo ∂S di S per scrivere il Teorema di Stokes. Esso sarà (SuperPlus[∂])S, ottenuto da un’orientamento positivo della circonferenza unitaria in (R^2) tramite p. In (R^2) la parametrizzazione che orienta positivamente la circonferenza unitaria rispetto al disco è (Cos(t), Sin(t)), t∈[0,2π], e la chiamiamo (SuperPlus[∂])D. Poi  p((SuperPlus[∂])D)=(Cos(t),Sin(t),1) immagine di (SuperPlus[∂])D tramite p=(x,y,(x^2)+(y^2)) è (SuperPlus[∂])S. Stokes si enuncia (∫_((SuperPlus[∂])S))F·d(SuperPlus[∂])S=(∫_S)rotF·(Subscript[ν, p])d(Subscript[σ, p]). Vediamo prima dei grafici

Grid[{{Show[ParametricPlot3D[{r Cos[t],r Sin[t],(r^2) },{r,0,1},{t,0,2 Pi},Mesh->None,PlotStyle->Opacity[0.7]],ParametricPlot3D[{Cos[t], Sin[t], 1},{t,0,2 Pi},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ImageSize->350,PlotRange->{{-1,1},{-1,1},{0,1}}],Show[Plot3D[(y^2)+(x^2),{x,-1,1},{y,-1,1},Mesh->None,PlotStyle->Opacity[0.7]],ParametricPlot3D[{r Cos[t], r Sin[t], 0},{t,0,2 Pi},{r,0,1},Mesh->None,PlotStyle->{Opacity[0.9]}],ParametricPlot3D[{Cos[t], Sin[t],1},{t,0,2 Pi},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{Cos[t], Sin[t], 0},{t,0,2 Pi},Mesh->None,PlotStyle->{Orange,Tube[0.02]}],ImageSize->350,PlotRange->{{-1,1},{-1,1},{0,1}},BoxRatios->{1,1,1/2}],Manipulate[Show[ParametricPlot3D[{Cos[t], Sin[t], 1},{t,0,T},Mesh->None,PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{Cos[t], Sin[t], 0},{t,0,T},Mesh->None,PlotStyle->{Orange,Tube[0.02]}],PlotRange->{{-1,1},{-1,1},{0,1}}],{T,0.0001,2 Pi}]},{Manipulate[Show[RegionPlot[(x^2)+(y^2)≤1,{x,-1,1},{y,-1,1},PlotStyle->{Opacity[0.1]},PerformanceGoal->"Quality"],ParametricPlot[{Cos[t],Sin[t]},{t,0,T},PlotStyle->{Orange,Thick}]],{T,0.0001,2Pi}]}}]

Calcoliamo i due integrali separatamente e vediamo se coincidono. In caso affermativo avremmo verificato Stokes, e scritto bene normale e orientazione compatibili

Integrate[({(y^2),x,(z^2)}/.{x->Cos[t],y->Sin[t],z->1}).{-Sin[t],Cos[t],0},{t,0,2 Pi}]

Integrate[((Curl[{(y^2),x,(z^2)},{x,y,z}]/.z->(x^2)+(y^2)).Cross[{1,0,2 x},{0,1,2 y}])*Boole[(x^2)+(y^2)≤1],{x,-1,1},{y,-1,1}]