Esercizio 1

Vogliamo mostrare per quali valori di a∈ℝ esiste finito l’integrale (∫_(ℝ^7))(1/(1+|x((|)^a)))dx. Integrando per sfere si ha (∫_(ℝ^7))(1/(1+|x((|)^a)))dx=(∫_0^(+∞))((∫_(∂B(0,r)))(1/(1+(r^a)))dσ)dr=(∫_0^(+∞))(1/(1+(r^a)))((r^6)7(Subscript[ω, 7]))dr. Ricordiamo infatti che in (ℝ^n)  la misura superficiale della sfera n-dimensionale di raggio r, S(∂B(0,r)), è S(∂B(0,r))=(r^(n-1))S(∂B(0,1)) e S(∂B(0,1)=(Subscript[nω, n]), con (Subscript[ω, n]) volume della palla unitaria in  (ℝ^n) . Per cui (∫_(∂B(0,r)))(1/(1+(r^a)))dσ=(1/(1+(r^a)))(∫_(∂B(0,r)))dσ=(1/(1+(r^a)))·S(∂B(0,r))=(1/(1+(r^a)))·(r^6)·7·(Subscript[ω, 7]). Quindi in definitiva dobbiamo trovare gli a∈ℝ per cui esiste finito l’integrale (∫_0^(+∞))((r^6)/(1+(r^a)))dr. Come prima cosa osserviamo che a>0. Se a≤0, allora per r->+∞ l’integranda andrebbe come (r^6), chiaramente non integrabile. Sia a >0. Vicino a 0 la funzione ((r^6)/(1+(r^a)))∼0 quindi è integrabile in 0. per r ∼+∞, ((r^6)/(1+(r^a)))∼(r^(6-a)) che è integrabile per r∼+∞ solo se 6-a+1<0, cioè per a>7. Proviamo

Integrate[((r^6)/(1+(r^a))),{r,0,+Infinity},Assumptions->a≤  7]

Integrate[((r^6)/(1+(r^a))),{r,0,∞},Assumptions->a>7]

Mostriamo il valore dell’integrale al variare di a. Per a che tende a 7 l’integrale esplode. Va a (1/7) per a che va a +∞

Plot[{(1/7),NIntegrate[((r^6)/(1+(r^a))),{r,0,+Infinity}]},{a,7.1,20},PlotRange->{{0,20},{0,10}},PlotStyle->{{Blue},{Red,Thick}},ImageSize->800]

Limit[((π Csc[((7 π)/a)])/a),a->+Infinity]

Esercizio 2

γ(t)=(t+Sin(t),0,1+Cos(t)), t∈[0,π]. Disegnamo il supporto di γ

Show[ParametricPlot3D[{(t+Sin[t]) ,0,1+Cos[t]},{t,0,Pi},PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{x,0,0},{x,-Pi,Pi},PlotStyle->{Black,Tube[0.01]}],ParametricPlot3D[{0,x,0},{x,-Pi,Pi},PlotStyle->{Black,Tube[0.01]}],ParametricPlot3D[{0,0,x},{x,0,2},PlotStyle->{Black,Tube[0.01]}],ImageSize->500,PlotRange->{{-Pi,Pi},{-Pi,Pi},{0,2}},AxesLabel->{X,Y,Z}]

Si ha: γ’(t)=(1+Cos(t),0,-Sin(t)). |γ’(t)|=(Sqrt[2+2 Cos(t)]), quindi la lunghezza di γ è data da l(γ)=(∫_γ)ds=(∫_0^π)|γ'(t)|dt. Per calcolare l’integrale osserviamo che (Sqrt[((1+Cos(t))/2)])=|Cos((t/2))|. Attenzione: il modulo è in generale importante: se t è tale che π≤t≤2π, allora cos((t/2))≤0, mentre noi abbiamo una radice, che è positiva. Nel nostro caso possiamo non scrivere il modulo perchè t∈[0,π]. Quindi ((∫_0)^π)(Sqrt[2(1+ Cos(t))])dt=((∫_0)^π)(Sqrt[2·2(((1+ Cos(t)))/2)])dt=((∫_0)^π)2|Cos((t/2))|dt=((∫_0)^π)2Cos((t/2))dt siccome per t∈[0,π], Cos((t/2))≥0. L’integrale ora si può calcolare a mano (Mathematica lo può fare direttamente se gli diamo la formula originale)

L=FullSimplify[Integrate[(Sqrt[2+2 Cos[t]]),{t,0,Pi}]]

FullSimplify[Integrate[2 Cos[t/2],{t,0,Pi}]]

La lunghezza di γ è l(γ)=4. Le coordinate del baricentro ((Subscript[x, g]),(Subscript[y, g]),(Subscript[z, g])) si trovano come ((((∫_γ)xds)/((∫_γ)ds)),(((∫_γ)yds)/((∫_γ)ds)),(((∫_γ)zds)/((∫_γ)ds))). Anche qui nel calcolo dell’integrale “a mano” useremo (Sqrt[((1+Cos(t))/2)])=|Cos((t/2))| e osserveremo che il modulo si può togliere. In seguito si integrerà per parti. Qui in Mathematica scriviamo direttamente la formula.

xg=FullSimplify[((Integrate[(t+Sin[t])*(Sqrt[2+2 Cos[t]]),{t,0,Pi}])/(Integrate[(Sqrt[2+2 Cos[t]]),{t,0,Pi}]))]

yg=FullSimplify[((Integrate[0,{t,0,Pi}])/(Integrate[(Sqrt[2+2 Cos[t]]),{t,0,Pi}]))]

zg=FullSimplify[((Integrate[(1+Cos[t])*(Sqrt[2+2 Cos[t]]),{t,0,Pi}])/(Integrate[(Sqrt[2+2 Cos[t]]),{t,0,Pi}]))]

Il baricentro ha coordinate (π-(4/3),0,(4/3)). La distanza del baricentro dall’asse z è (Subscript[x, g]) (l’ascissa del baricentro, vedi figura).

Show[ParametricPlot3D[{(t+Sin[t]) ,0,1+Cos[t]},{t,0,Pi},PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{Pi-(4/3)+t ((4/3)-Pi),0,(4/3)},{t,0,1},PlotStyle->{Orange,Tube[0.02]}],ListPointPlot3D[{{Pi-(4/3),0,(4/3)}},PlotStyle->{PointSize[0.02]}],ParametricPlot3D[{x,0,0},{x,-Pi,Pi},PlotStyle->{Black,Tube[0.01]}],ParametricPlot3D[{0,x,0},{x,-Pi,Pi},PlotStyle->{Black,Tube[0.01]}],ParametricPlot3D[{0,0,x},{x,0,2},PlotStyle->{Black,Tube[0.01]}],ImageSize->700,PlotRange->{{-Pi,Pi},{-Pi,Pi},{0,2}},AxesLabel->{X,Y,Z}]

Mostriamo la superficie di rotazione ottenuta ruotango il supporto di γ attorno all’asse z di un angolo di 2π.

Manipulate[Show[ListPointPlot3D[{{(-(4/3)+π),0,(4/3)}},PlotStyle->{PointSize[0.03]}],ParametricPlot3D[{(t+Sin[t]) Cos[s],(t+Sin[t]) Sin[s],1+Cos[t]},{t,0,Pi},{s,0,T},PerformanceGoal->"Quality",Mesh->None,PlotStyle->{Opacity[0.6]}],ParametricPlot3D[{(t+Sin[t]) ,0,1+Cos[t]},{t,0,Pi},PlotStyle->{Red,Tube[0.02]}],ImageSize->500,PlotRange->{{-Pi,Pi},{-Pi,Pi},{0,2}}],{T,0.0001,2 Pi}]

Dal Teorema di Guldino sappiamo che l’area di questa superficie è data da 2π·(Subscript[x, g])·l(γ)

Aγ=2 Pi xg L

Esercizio 3

Dobbiamo calcolare un integrale su una superficie cartesiana y=(x^2)+4z (sia S). Essa è quindi parametrizzata da p(x,z)=((Subscript[p, 1])(x,z),(Subscript[p, 2])(x,z),(Subscript[p, 3])(x,z))=(x,(x^2)+4z,z), con (x,z)∈[0,2]×[0,2]. Abbiamo sia la parametrizzazione che il suo dominio D=[0,2]×[0,2]. (S in rosso, D in blu: S è il grafico di una funzione da (ℝ^2)  in ℝ, solo che a differenza dei casi che ci sono capitati, il dominio (ℝ^2) è pensato come il piano xz).

Show[ParametricPlot3D[{x,0,z},{x,0,2},{z,0,2},Mesh->None,PlotStyle->{Blue,Opacity[0.6]}],ParametricPlot3D[{x,(x^2)+4 z,z},{x,0,2},{z,0,2},Mesh->None,PlotStyle->{Red,Opacity[0.9]}],ImageSize->900,PlotRange->All]

L’integrale è (∫_S)xdσ=(∫_D)(Subscript[p, 1])(x,z)|((∂p)/(∂z))×((∂p)/(∂x))|dxdz. Ricordiamo che l’elemento di superficie dσ data la parametrizzazione p della superficie è dσ=|((∂p)/(∂z))×((∂p)/(∂x))|dxdz.

MatrixForm[Grad[{x,(x^2)+4 z,z},{z,x}]]

(Subscript[A, S])=Integrate[x*Norm[Cross[{0,4,1},{1,2 x,0}]],{x,0,2},{z,0,2}]

Esercizio 4

E={(x,y,z)∈(ℝ^3): 9(((1-(Sqrt[(x^2)+(y^2)])))^2)+4(z^2)≤ 1}. Riscriviamo questo insieme non nelle coordinate cartesiane (x,y,z) ma in coordinate cilindriche (sono quelle che ci permettono di individuare se un insieme è invariante per una rotazione intorno all’asse z, ovvero se l’insieme è un solido di rotazione attorno all’asse z). Queste sono (r,θ,z). La trasformazione è x=r Cos(θ), y=r Sin(θ),z=z. r descrive la distanza del punto dall’asse z. θ descrive l’angolo formato dalle coordinate (x,y) del punto sul piano xy con l’asse x>0. z descrive la quota z del punto (è la stessa coordinata cartesiana z, la quota del punto sull piano xy). Mostriamo velocemente le coordinate cilindriche

Manipulate[Show[ParametricPlot3D[{0,0,z},{z,0,Z},PlotStyle->{Green,Tube[0.02]}],ParametricPlot3D[{r Cos[t],r Sin[t],Z},{r,0,R},{t,0,T},Mesh->None,PerformanceGoal->"Quality",PlotStyle->{Blue,Opacity[0.5]}],ParametricPlot3D[{r Cos[T], r Sin[T],Z},{r,0,R},PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{x,0,0},{x,-2,2},PlotStyle->{Black,Tube[0.01]}],ParametricPlot3D[{0,x,0},{x,-2,2},PlotStyle->{Black,Tube[0.01]}],ParametricPlot3D[{0,0,x},{x,-2,2},PlotStyle->{Black,Tube[0.01]}],ListPointPlot3D[{{R Cos[T],R Sin[T],Z}},PlotStyle->{PointSize[0.02]}],ImageSize->750,PlotRange->{{-2,2},{-2,2},{-2,2}}],{R,0.0001,2},{T,0.0001,2 Pi},{Z,-2,2}]

r è il segmento in rosso, z quello in verde, θ l’angolo in blu. Si ha per r, dalla trasformazione di coordinate, che r=(Sqrt[(x^2)+(y^2)]). Quindi in coordinate cilindriche l’insieme E è descritto dalla relazione  9(((1-r))^2)+4(z^2)≤ 1, quindi E dipende solo da r e da z. In altre parole, se un punto descritto da ((Subscript[r, 1]),(Subscript[θ, 1]),(Subscript[z, 1])) è in E per un certo (Subscript[θ, 1]), allora per ogni θ∈[0,2π] i punti ((Subscript[r, 1]),θ,(Subscript[z, 1])) sono su E. Cioè se un punto è sull’insieme E, allora tutta la circonferenza descritta da quel punto attorno all’asse z è in E. Quindi E è invariante per rotazione attorno all’asse z. Quindi basta limitarci a considerare un semipiano (ad esempio il semipiano xz con x>0) e individuare la sezione su questo semipiano dell’insieme E. Tutto E sarà ottenuto ruotando questa sezione (che chiamiamo D) attorno all’asse z. Il piano xz ,x>0 è descritto da y=0,x>0. Nell’equazione di E abbiamo E⋂{xy,x>0}={(x,y,z)∈(ℝ^3): 9(((1-x))^2)+4(z^2)≤ 1}. Sul piano xz questa è l’equazione di un’ellisse di centro x=1,z=0 e semiassi (1/3) e (1/2). Vediamola sul piano xz

RegionPlot[9 (((1-x))^2)+4 (z^2)≤1,{x,1-(1/3),1+(1/3)},{z,-(1/2),(1/2)},PlotRange->{{0,1+(1/3)},{-(1/2),(1/2)}},AspectRatio->Automatic]

Vediamo D sul piano xz in (ℝ^3) e ruotiamolo attorno all’asse z. Disegnamo accanto il solido E descritto con la disuguaglianza data dall’esercizio. Sono lo stesso solido. Quindi E è dato dalla rotazione di D attorno all’asse z.

Grid[{{Manipulate[Show[ParametricPlot3D[{1+(r/3) Cos[t],0,(r/2) Sin[t]},{r,0,1},{t,0,2 Pi},Mesh->None,PlotStyle->{Opacity[1]}],ParametricPlot3D[{(1+(1/3) Cos[t]) Cos[s],(1+(1/3) Cos[t]) Sin[s],(1/2) Sin[t]},{s,0,T},{t,0,2 Pi},Mesh->None,PlotStyle->{Opacity[0.85]},PerformanceGoal->"Quality"],ImageSize->400,AxesLabel->{X,Y,Z},PlotRange->{{-(5/3),(5/3)},{-(5/3),(5/3)},{-(1/2),(1/2)}},BoxRatios->{(5/3),(5/3),(1/2)}],{T,0.0001,2 Pi}],RegionPlot3D[9 (((1-(Sqrt[(x^2)+(y^2)])))^2)+4 (z^2)≤ 1,{x,-(5/3),(5/3)},{y,-(5/3),(5/3)},{z,-(1/2),(1/2)},Mesh->None,PlotPoints->40,ImageSize->400,AspectRatio->Automatic,BoxRatios->{(5/3),(5/3),(1/2)}]}}]

Il baricentro di un’ellisse è il suo centro, che nel nostro caso è il punto (1,0,0). La distanza del baricentro dall’asse z è quindi 1 (ascissa del baricentro). L’area dell’ellisse è π·(1/2)·(1/3)=(π/6) (area dell’ellisse di semiassi a e b è π·a·b). Il volume del solido è 2π·Area(D)·(Subscript[x, b]) ((Subscript[x, b])  distanza del baricentro dall’asse di rotazione, nel nostro caso appunto corrisponde all’ascissa del baricentro)

VolE=2 Pi (Pi/6)

Esercizio 5

Disegnamo l’insieme E. Siccome non è specificato se siamo in un semipiano (x>0 o x<0) l’insieme E è composto da due componenti (la descrizione a parole dell’esercizio ci dice che è compreso tra le iperboli e le rette. Se disegnamo queste quattro curve vediamo che la regione si compone di due componenti connesse)

Show[ContourPlot[{(x^2)-(y^2)==1,(x^2)-(y^2)==2,y==-(1/2)  x,y==(1/2) x},{x,-3,3},{y,-3,3},ContourStyle->{{Orange,Thick},{Red,Thick},{Purple,Thick},{Blue,Thick}},AspectRatio->Automatic,AxesLabel->{x,y},PerformanceGoal->"Quality"],RegionPlot[ {-(1/2) x<y<(1/2) x&&(Sqrt[1+(y^2)])<x<(Sqrt[2+(y^2)]) },{x,-3,3},{y,-3,3},PerformanceGoal->"Quality"],RegionPlot[ {(1/2) x<y<-(1/2) x&&-(Sqrt[2+(y^2)])<x<-(Sqrt[1+(y^2)]) },{x,-3,3},{y,-3,3},PerformanceGoal->"Quality"]]

Dobbiamo calcolare (∫_E)(Sqrt[(x^2)-(y^2)])dxdy. Stiamo integrando una funzione pari ((Sqrt[(x^2)-(y^2)]))  su un insieme che è simmetrico rispetto all’asse x=0 (asse y). Per cui basta calcolare l’integrale (∫_(E⋂{x>0}))(Sqrt[(x^2)-(y^2)])dxdy. L’integrale cercato sarà il doppio. Calcoliamo solo l’integrale cercato sulla regione compresa nel semipiano x>0. Il cambio di variabile opportuno è u=(x^2)-(y^2), v=(y/x).

Show[ContourPlot[{(x^2)-(y^2)==1,(x^2)-(y^2)==2,y==-(1/2)  x,y==(1/2) x},{x,0,3},{y,-3,3},ContourStyle->{{Orange,Thick},{Red,Thick},{Purple,Thick},{Blue,Thick}},AspectRatio->Automatic,AxesLabel->{x,y},PerformanceGoal->"Quality"],RegionPlot[ {-(1/2) x<y<(1/2) x&&(Sqrt[1+(y^2)])<x<(Sqrt[2+(y^2)]) },{x,0,3},{y,-3,3},PerformanceGoal->"Quality"]]

Si ha u∈[1,2], v∈[-(1/2),(1/2)] (quindi, se denominiamo come T la traformazione (x,y)=T(u,v) , si ha che D=(T^(-1))(E)=[1,2]×[-(1/2),(1/2)]). Calcoliamo il determinante dello jacobiano della trasformazione (x,y)=T(u,v). Noi abbiamo la trasformazione inversa (u,v)=(T^(-1))(x,y). Si ha Det[D(T(u,v))]=(1/(Det[D((T^(-1)))(T(u,v)])).

(1/(Det[Grad[{(x^2)-(y^2),(y/x)},{x,y}]]))

siccome (y/x)=v, si ha Det[D(T(u,v))]=(1/(2(1-(v^2)))). Si vede che è positivo siccome v∈[-(1/2),(1/2)]. Alternativamente scriviamo prima (T^(-1)) invertendo T (esprimiano x,y in funzione di u,v). x=(Sqrt[(u/(1-(v^2)))]), y=v(Sqrt[(u/(1-(v^2)))]). E cacloliamone il determinante della matrice jacobiana.

FullSimplify[Det[Grad[{(Sqrt[(u/(1-(v^2)))]),v (Sqrt[(u/(1-(v^2)))])},{u,v}]]]

Che è lo stesso. Con questo cambiamento di variabili (∫_(E⋂{x>0}))(Sqrt[(x^2)-(y^2)])dxdy=(∫_D)((Sqrt[u])/(2(1-(v^2))))dudv. Calcoliamolo l’integrale (suggerimento: (∫_D)((Sqrt[u])/(2(1-(v^2))))dudv=((∫_1^2)(Sqrt[u])du)((∫_(-(1/2))^(1/2))(1/(2(1-(v^2))))dv). Osserviamo che (Sqrt[u]) si integra con (2/3)(u^(3/2)), mentre (1/(1-(v^2)))=(1/2)((1/(1+v))+(1/(1-v))), (1/(1+v)) si integra con Log(1+v), (1/(1-v)) con Log(1-v).) Ad ogni modo calcoliamolo direttamente con Mathematica

Integrate[((Sqrt[u])/(2 (1-(v^2)))),{u,1,2},{v,-(1/2),(1/2)}]

Calcoliamo con Mathematica l’integrale nella sua forma originale

FullSimplify[Integrate[(Sqrt[(x^2)-(y^2)])*Boole[1≤ (x^2)-(y^2)≤ 2&&-(1/2)≤ (y/x)≤ (1/2)],{x,1,2},{y,-2,2}]]

Esercizio 6

G è il solido ottenuto ruotando attorno all’asse z il disco sul piano xz di centro (10,0,0) e raggio uno e intersecandolo col semipiano z≥0. Sia S la frontiera di G, composta da (Subscript[S, 1]), la parte superiore di S, ed (Subscript[S, 2]), la parte inferiore di S. Sia poi F(x,y,z)=((x^2)-(y/((x^2)+(y^2))),x+(x/((x^2)+(y^2))),z+y). Determinare (Subscript[I, 1]),(Subscript[I, 2]),(Subscript[I, 0]) , ovvero il flusso uscente da S attraverso (Subscript[S, 1]) , il flusso uscente da S attraverso (Subscript[S, 2]) e il flusso uscente da tutta S.

Grid[{{Show[ContourPlot3D[(((10-(Sqrt[(x^2)+(y^2)])))^2)+(z^2)==4,{x,-12,12},{y,-12,12},{z,0,2},Mesh->None,ContourStyle->{Opacity[0.7]}],ParametricPlot3D[{r Cos[t],r Sin[t],0},{r,8,12},{t,0,2 Pi},Mesh->None,PlotStyle->{Opacity[0.7]}],PlotRange->{{-12,12},{-12,12},{0,2}},ImageSize->400,BoxRatios->{12,12,1}],Show[ParametricPlot3D[{r Cos[t],r Sin[t],0},{r,8,12},{t,0,2 Pi},Mesh->None,PlotStyle->{Opacity[0.7]}],Graphics3D[Arrow[{{10,0,0},{10,0,-3}}]],Graphics3D[Arrow[{{-10,0,0},{-10,0,-3}}]],Graphics3D[Arrow[{{0,10,0},{0,10,-3}}]],Graphics3D[Arrow[{{0,-10,0},{0,-10,-3}}]],ImageSize->400,PlotRange->{2,-3}]}}]

Calcoliamo il flusso uscente attraverso (Subscript[S, 2]), cioè la base. La superficie è parametrizzata da p(x,y)=(x,y,0) con (x,y)∈D, D={(x,y)∈(ℝ^2):64≤(x^2)+(y^2)≤ 144} è la corona di raggi 8 e 12 sul piano xy. Siccome questa superficie cartesiana è la base del solido G, a noi serve il vettore uscente, che è -((∂p)/(∂x))×((∂p)/(∂y))=(0,0,-1). Per cui (Subscript[I, 2])=(∫_D)F(x,y,0)·(0,0,-1)dxdy=(∫_D)0dxdy.

{(x^2)-(y/((x^2)+(y^2))), x+(x/((x^2)+(y^2))),z+y}/.z->0

I2=FullSimplify[Integrate[({(x^2)-(y/((x^2)+(y^2))),x+(x/((x^2)+(y^2))),y}.{0,0,-1})*Boole[64≤(x^2)+(y^2)≤ 144],{x,-12,12},{y,-12,12}]]

Calcoliamo con il Teorema della divergenza il flusso (Subscript[I, 0]) cioè il flusso uscente attraverso tutta la superficie di G: (Subscript[I, 0])=(∫_G)divFdxdydz.

Div[{(x^2)-(y/((x^2)+(y^2))), x+(x/((x^2)+(y^2))),z+y},{x,y,z}]

Dobbiamo calcolare l’integrale pieno (∫_G)1+2xdxdydz=(∫_G)dxdydz+2(∫_G)xdxdydz=Vol(G)+2(∫_G)xdxdydz. Il secondo integrale è nullo: il dominio G è simmetrico rispetto al piano yz (quindi rispetto alle x) e la funzione è dispari in x. Il primo integrale è il volume di G, che è metà del volume del toro. Il volume del toro ottenuto ruotando il disco ci centro (10,0,0) e raggio 2 è dato da 2π·10·4π, dove 10 è la distanza del baricentro dall’asse z (il baricentro del disco è il suo centro) e 4π è l’area. Quindi il volume di G, essendo la metà, è 40(π^2). Controlliamo

Integrate[(1+2 x)*Boole[z≤ (Sqrt[4-(((10-(Sqrt[(x^2)+(y^2)])))^2)])],{x,-12,12},{y,-12,12},{z,0,2}];

I0=Integrate[(1+2 Cos[t]) r * (Sqrt[4-(((10-r))^2)]),{r,8,12},{t,0,2 Pi}]

Chiaramente il flusso uscente dalla superficie (Subscript[S, 1]) è il flusso uscente da tutta S, siccome il flusso uscente attraverso (Subscript[S, 2]) è nullo.

I1=I0-I2;

Esercizio 7

Disegnamo l’asteroide 𝒜. Vediamo di più che la parametrizzazione data dà un orientamento positivo all’asteroide come bordo della regione D che racchiude.

Manipulate[ParametricPlot[{((Cos[t])^3),((Sin[t])^3)},{t,0,T},PlotStyle->{Red,Thick},PlotRange->{{-1,1},{-1,1}}],{T,0.0001,2 Pi}]

Per calcolare l’area di D, siccome la parametrizzazione orienta positivamente il bordo, usiamo la formula dell’area derivante dalla Formula di Green: Area(D)=(1/2)((∫_𝒜)xdy-(∫_𝒜)ydx)=(1/2)(∫_0^(2π))3 ((Cos(t))^4)(Sin^2)(t)+3(Sin^4)(t)(Cos^2)(t)dt=(3/2)(∫_0^(2π)) (4/4)(Cos^2)(t)(Sin^2)(t)dt=(3/8)(∫_0^(2π))(Sin^2)(2t)dt=(3/8)(∫_0^(2π))((1-Cos(4t))/2)dt=((3π)/8)

Integrate[(1/2) (((Cos[t])^3) *3*((Sin[t])^2)*Cos[t]+3*((Sin[t])^3)*((Cos[t])^2)*Sin[t]),{t,0,2 Pi}]

Se consideriamo il primo quadrante (x>0, y>0), possiamo mostrare che l’arco di 𝒜 contenuto nel primo quadrante è anche dato implicitamente dall’equazione cartesiana ((((y^(2/3))+(x^(2/3))))^(3/2))=1. Quindi possiamo esprimerlo come grafico di una funzione y=(((1-(x^(2/3))))^(3/2)) e possiamo calcolare l’area compresa tra questo arco e gli assi y>0 e l’asse x>0 come integrale di questa funzione. L’area dell’asteroide sarà quattro volte l’area così trovata

Plot[(((1-(x^(2/3))))^(3/2)),{x,0,1},PlotStyle->{Red,Thick},AspectRatio->Automatic]

Integrate[4*(((1-(x^(2/3))))^(3/2)),{x,0,1}]

Esercizio 8

Disegnamo il sostegno di γ. Se chiamiamo x=1+Cos(t), y=1+Sin(t), z=1-Cos(t)-Sin(t) vediamo che la relazione tra le coordinate dei punti sul sostegno di γ è z=3-x-y. Per cui il sostegno di γ giace su questo piano. In più il sostegno di γ è l’immagine della circonferenza unitaria centrata in (1,1) sul piano xy tramite la funzione (x,y,3-x-y). E’ quindi anche il bordo della superficie immagine tramite la funzione (x,y,3-x-y) del disco unitario centrato in (1,1) sul piano xy. Chiamiamo p la parametrizzazione p(x,y)=(x,y,3-x-y), D il disco unitario centrato in (1,1), ∂D la circonferenza unitaria centrata in (1,1), S la superficie p(D). Riconosciamo che il sostegno di γ è p(∂D), che chiamiamo ∂S, bordo della superficie S. Notiamo che la parametrizzazione di γ proviene da una parametrizzazione di ∂D che lo orienta positivamente. Quindi γ è p((SuperPlus[∂])D), cioè (SuperPlus[∂])S.

Grid[{{Manipulate[Show[ParametricPlot3D[{1+Cos[t],1+Sin[t],0},{t,0,s},PlotStyle->{Orange,Tube[0.02]}],ParametricPlot3D[{1+r Cos[t],1+r Sin[t],0},{t,0,2 Pi},{r,0,1},Mesh->None,PlotStyle->{Opacity[0.8]},PerformanceGoal->"Quality"],ParametricPlot3D[{1+Cos[t],1+Sin[t],1-Sin[t]-Cos[t]},{t,0,s},PlotStyle->{Red,Tube[0.02]}],ParametricPlot3D[{1+r Cos[t],1+r Sin[t],1-r Cos[t]-r Sin[t]},{t,0,2 Pi},{r,0,1},Mesh->None,PlotStyle->{Opacity[0.8]},PerformanceGoal->"Quality"],PlotRange->{{0,2},{0,2},{-1,3}}],{s,0.0001,2 Pi}],Manipulate[Show[RegionPlot[(((x-1))^2)+(((y-1))^2)≤1,{x,0,2},{y,0,2},PerformanceGoal->"Quality"],ParametricPlot[{1+Cos[t],1+Sin[t]},{t,0,T},PlotStyle->{Orange,Thick}]],{T,0.001,2 Pi}]}}]

La notazione (∫_γ)((ye)^x)dx+((x^2)+(e^x))dy+(z^2)(e^z)dz equivale a (∫_γ)F·dγ, dove F =(((ye)^x),(x^2)+(e^x),(z^2)(e^z)). Per Stokes, (∫_γ)F·dγ=(∫_((SuperPlus[∂])S))F·d(SuperPlus[∂])S=(∫_S)rot F·(Subscript[ν, p])d(Subscript[σ, p])

MatrixForm[Grad[{x,y,3-x-y},{x,y}]]

Integrate[((Curl[{y Exp[x],(x^2)+Exp[x],(z^2) Exp[z]},{x,y,z}]/.z->3-x-y).Cross[{1,0,-1},{0,1,-1}])*Boole[(((x-1))^2)+(((y-1))^2)≤ 1],{x,0,2},{y,0,2}]

Esercizio 9

Disegnamo il campo F(x,y)=(-((3(x^3)+(xy^2))/(Sqrt[(x^2)+(y^2)])),(((x^2)y+3(y^3))/(Sqrt[(x^2)+(y^2)]))). Mostriamo che è irrotazionale

VectorDensityPlot[{-((3 (x^3) +x (y^2))/(Sqrt[(x^2)+(y^2)])),(((x^2) y+3 (y^3))/(Sqrt[(x^2)+(y^2)]))},{x,-3,3},{y,-3,3}]

FullSimplify[D[(((x^2) y+3 (y^3))/(Sqrt[(x^2)+(y^2)])),x]-D[-((3 (x^3) +x (y^2))/(Sqrt[(x^2)+(y^2)])),y]]

Esso è irrotazionale. Siccome è definito su (ℝ^2)∖{(0,0)} che è un semplicemente connesso privato di un punto, esso è conservativo se e solo se l’integrale di linea su un qualsiasi circuito attorno allo 0 è nullo. Calcoliamo la circuitazione di F sul circolo unitario (Cos(t),Sin(t)), t∈[0,2π]. (∫_(∂B(0,1)))F·d∂B(0,1)=(∫_0^(2π))(-3 (Cos^3)(t)-Cos(t)(Sin^2)(t),(Cos^2)(t)Sin(t)+3(Sin^3)(t))·(-Sin(t),Cos(t))dt=(∫_0^(2π))4 Sin(t)Cos(t)dt=2(∫_0^(2π))Sin(2t)dt=0.

Integrate[({-((3 (x^3) +x (y^2))/(Sqrt[(x^2)+(y^2)])),(((x^2) y+3 (y^3))/(Sqrt[(x^2)+(y^2)]))}/.{x->Cos[t],y->Sin[t]}).{-Sin[t],Cos[t]},{t,0,2 Pi}]

Quindi il campo F è conservativo. Calcoliamone le primitive. Integriamo prima in x (Si svolge osservando che si può raccogliere x: ∫-((x(3(x^2)+(y^2)))/(Sqrt[(x^2)+(y^2)]))dx e si usa il cambio di variabile (x^2)=t, 2xdx=dt. Quindi si deve calcolare -(1/2)∫((3t+(y^2))/(Sqrt[t+(y^2)]))dt=-(1/2)∫((3t+3(y^2)-2(y^2))/(Sqrt[t+(y^2)]))dt=-(1/2)(3∫(Sqrt[t+(y^2)])dt-2(y^2)∫(1/(Sqrt[t+(y^2)]))dt). Si osserva che (Sqrt[t+(y^2)])  si integra come (2/3)(((t+(y^2)))^(3/2)), (1/(Sqrt[t+(y^2)])) si integra con 2(Sqrt[t+(y^2)]). Si sostituisce t=(x^2) e si aggiunge g(y) siccome l’integrale indefinito è in x, si deve aggiungere una funzione costante in x, cioè una generica g(y). Svolgendo i conti si ottiene -((x^2)-(y^2))(Sqrt[(x^2)+(y^2)])+g(y).

Integrate[-((3 (x^3) +x (y^2))/(Sqrt[(x^2)+(y^2)])),x]

Il potenziale U(x,y) tale che F=∇U è U(x,y)=-((x^2)-(y^2))(Sqrt[(x^2)+(y^2)])+g(y). Deriviamo rispetto ad y.

FullSimplify[D[-((x^2)-(y^2)) (Sqrt[(x^2)+(y^2)])+g[y],y]]

Siccome (∂_y)U=(((x^2)y+3(y^3))/(Sqrt[(x^2)+(y^2)])), allora g’(y)=0, quindi g(y)=c, c∈ℝ. Per cui U(x,y)=-((x^2)-(y^2))(Sqrt[(x^2)+(y^2)])+c, c∈ℝ. Siccome il campo è conservativo, l’integrale (∫_α)F·dα, dove α(t)=(Cos(t),(((Sin(t)+Cos(t)))^3)), t∈[0,π] è dato da (∫_α)F·dα=U(α(π))-U(α(0))=0.

U[x_,y_]:=-((x^2)-(y^2)) (Sqrt[(x^2)+(y^2)]);
α1[t_]:=Cos[t];
α2[t_]:=(((Sin[t]+Cos[t]))^3);

U[α1[Pi],α2[Pi]]-U[α1[0],α2[0]]

Show[VectorDensityPlot[{-((3 (x^3) +x (y^2))/(Sqrt[(x^2)+(y^2)])),(((x^2) y+3 (y^3))/(Sqrt[(x^2)+(y^2)]))},{x,-3,3},{y,-3,3}],ParametricPlot[{Cos[t],(((Sin[t]+Cos[t]))^3)},{t,0,Pi},PlotStyle->{Red,Thick}]]